Question

易语言如何通过进程名称来获取该进程窗口的句柄

Answer 1

只能获取最前的那个窗口句柄
.版本 2
.子程序 进程_名取句柄0, 整数型, , 找不到将返回0
.参数 进程名, 文本型
.局部变量 sHandle, 整数型
.局部变量 Pn, PROCESSENTRY32
.局部变量 lpTe, THREADENTRY32
.局部变量 Found, 整数型
.局部变量 ret, 整数型
.局部变量 sThread, 整数型
.局部变量 tFound, 整数型
sHandle ＝ CreateToolhelp32Snapshot (15, 0)
Pn.dwsize ＝ 296
Found ＝ Process32First (sHandle, Pn)
.判断循环首 (Found ≠ 0)
.如果真 (到小写 (到文本 (Pn.szExefile)) ＝ 到小写 (进程名))
sThread ＝ CreateToolhelp32Snapshot (4, 0)
lpTe.dwSize ＝ 28
tFound ＝ Thread32First (sThread, lpTe)
.判断循环首 (tFound ≠ 0)
.如果真 (lpTe.th32OwnerProcessID ＝ Pn.th32ProcessID)
EnumThreadWindows (lpTe.th32ThreadID, &EnumThreadWndProc, ret)
跳出循环 ()
.如果真结束
tFound ＝ Thread32Next (sThread, lpTe)
.判断循环尾 ()
CloseHandle (sThread)
跳出循环 ()
.如果真结束
Found ＝ Process32Next (sHandle, Pn)
.判断循环尾 ()
CloseHandle (sHandle)
返回 (ret)
.子程序 EnumThreadWndProc, 整数型
.参数 hwnd, 整数型
.参数 lParam, 整数型, 参考
.局部变量 lHwnd1, 整数型
.局部变量 lHwnd2, 整数型
lHwnd1 ＝ GetParent (hwnd)
.判断循环首 (lHwnd1 ≠ 0) ' 用取父窗口的方法,循环找到他祖宗.... :)
lHwnd2 ＝ lHwnd1
lHwnd1 ＝ GetParent (lHwnd1)
.判断循环尾 ()
.如果真 (lHwnd2 ≠ 0)
lParam ＝ lHwnd2
返回 (0)
.如果真结束
返回 (1)
.版本 2
.DLL命令 CreateToolhelp32Snapshot, 整数型
.参数 dwFlags, 整数型
.参数 th32ProcessID, 整数型
.DLL命令 Process32First, 整数型
.参数 hSnapShot, 整数型
.参数 uProcess, PROCESSENTRY32
.DLL命令 Thread32First, 整数型, "KERNEL32.DLL", "Thread32First"
.参数 hSnapshot, 整数型
.参数 lpte, THREADENTRY32
.DLL命令 EnumThreadWindows, 整数型, "user32", "EnumThreadWindows"
.参数 dwThreadId, 整数型
.参数 lpfn, 子程序指针
.参数 lParam, 整数型, 传址
.DLL命令 Thread32Next, 整数型, "KERNEL32.DLL", "Thread32Next"
.参数 hSnapshot, 整数型
.参数 lpte, THREADENTRY32
.DLL命令 CloseHandle, 整数型, "kernel32"
.参数 hObject, 整数型
.DLL命令 Process32Next, 整数型
.参数 hSnapShot, 整数型
.参数 uProcess, PROCESSENTRY32
.DLL命令 GetParent, 整数型, "user32", "GetParent"
.参数 hwnd, 整数型
.版本 2
.数据类型 PROCESSENTRY32
.成员 dwsize, 整数型, , , 296
.成员 cntusage, 整数型, , , 引用数
.成员 th32ProcessID, 整数型, , , 进程标识符
.成员 th32defaultheapid, 整数型, , , 默认堆ID
.成员 th32moduleid, 整数型, , , 进程模块标识符
.成员 cntthreads, 整数型, , , 线程数
.成员 th32ParentProcessID, 整数型, , , 父进程标识符
.成员 pcpriclassbase, 整数型, , , 线程优先权
.成员 dwflags, 整数型
.成员 szExefile, 字节型, , "260", 进程名称
.数据类型 THREADENTRY32
.成员 dwSize, 整数型
.成员 cntUsage, 整数型
.成员 th32ThreadID, 整数型
.成员 th32OwnerProcessID, 整数型
.成员 tpBasePri, 整数型
.成员 tpDeltaPri, 整数型
.成员 dwFlags, 整数型

Answer 2

用api吧，或者用超级模块。而且一个进程不止单单一个窗口的，要枚举的。

Answer 3

提取进程（“”）