Question

as3.0中如何画两点间的虚线

最好是函数形式，直接输入两点坐标就可以画出的。
求高手写出这个函数！！！！！！！！

Answer 1

import flash.geom.Point;
/** * 画虚线
*
* @param graphics <b> Graphics</b>
* @param beginPoint <b> Point </b> 起始点坐标
* @param endPoint <b> Point </b> 终点坐标
* @param width <b> Number </b> 虚线的长度
* @param grap <b> Number </b> 虚线短线之间的间隔
*/
function drawDashed(graphics:Graphics, beginPoint:Point, endPoint:Point, width:Number, grap:Number):void
{
if (!graphics || !beginPoint || !endPoint || width <= 0 || grap <= 0) return;

var Ox:Number = beginPoint.x;
var Oy:Number = beginPoint.y;

var radian:Number = Math.atan2(endPoint.y - Oy, endPoint.x - Ox);
var totalLen:Number = Point.distance(beginPoint, endPoint);
var currLen:Number = 0;
var x:Number, y:Number;

while (currLen <= totalLen)
{
x = Ox + Math.cos(radian) * currLen;
y = Oy +Math.sin(radian) * currLen;
graphics.moveTo(x, y);

currLen += width;
if (currLen > totalLen) currLen = totalLen;

x = Ox + Math.cos(radian) * currLen;
y = Oy +Math.sin(radian) * currLen;
graphics.lineTo(x, y);

currLen += grap;
}

}

this.graphics.lineStyle(1,0xFF0000)
drawDashed(this.graphics, new Point(10,10), new Point(200,200), 15, 20)

Answer 2

你可以使用画直线的API，把直线切成线段，一段一段地画。

Answer 3

as3没有提供这样的API，自己写

Answer 4

这个需要自己写啦