Question

怎样在以下批处理里添加进度条，安装第一个是10%第二个是20%

ping -n 1 127.0.0.1>soft.txt
call 迅雷标准版.exe
ping -n 1 127.0.0.1>soft.txt
CALL QQ游戏.exe
call 暴风影音5.exe
ping -n 1 127.0.0.1>soft.txt

Answer 1

@echo off
:JDAZ
rem 进度安装(此处不能有显示代码)
call :getbs
call :JDT 0
call :_setup "迅雷标准版.exe"
call :JDT 10
call :_setup "QQ游戏.exe"
call :JDT 20
call :_setup "暴风影音5.exe"
call :JDT 30
ping 1 -w 2000>nul
call :JDT 50
ping 1 -w 2000>nul
call :JDT 80
ping 1 -w 3000>nul
call :JDT 100
echo.
rem 进度安装结束
pause
exit
:getbs
rem 获取退格符
for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "bs=%%a"
exit/b
:JDT
rem 进度条 %1
for /l %%i in (1,1,10) do set /p=%bs%%bs%%bs%%bs%%bs%%bs%%bs%%bs%<nul
if %1 lss 100 (set/p=正在安装... <nul) else set/p=安装完毕。 <nul
set /a num1=%1/5
if %num1% neq 0 for /l %%i in (1,1,%num1%) do set /p=■<nul
set /a num2=20-%num1%
if %num2% neq 0 for /l %%i in (1,1,%num2%) do set /p=□<nul
set /p=%1%%<nul
exit /b
:_setup
rem 安装程序
title 正在安装 %~1
if exist "%~1" (start /wait "" "%~1" >nul) else exit /b
exit /b

Answer 2

参考这个添加
@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . .
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 4) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo 10%%
echo └──────────────────────────────────────┘
pause
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 8) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo 20%%
echo └──────────────────────────────────────┘
pause