Question

易语言用edb数据库制作一个注册登录的软件

求源码，最好说明怎么在数据库上加入账号和密码，然后注册时会在数据库上查找，如果有相同的账号，就提示错误，如果注册成功，就可以登录了，怎么做，求求啊，源码哦，我觉得好了20分就是你的了！

Answer 1

.版本 2
.支持库 dp1
.子程序 __启动窗口_创建完毕
输出调试文本 (打开 (取运行目录 () ＋ “\数据库.edb”, , , , , , ))
' 创建EDB ()
.子程序 创建EDB, , , 本程序只用一次就可以了
.局部变量 字段信息, 字段信息, , "2"
字段信息 [1].名称 ＝ “用户名”
字段信息 [1].类型 ＝ #文本型
字段信息 [1].最大文本长度 ＝ 20
字段信息 [2].名称 ＝ “密码”
字段信息 [2].类型 ＝ #文本型
字段信息 [2].最大文本长度 ＝ 32
创建 (取运行目录 () ＋ “\数据库.edb”, 字段信息)

.子程序 _按钮1_被单击, , , 登录
.局部变量 用户名, 文本型
.局部变量 密码, 文本型

.如果真 (编辑框1.内容 ＝ “”)
信息框 (“请输入您的帐号！”, #错误图标, )
编辑框1.获取焦点 ()
返回 ()
.如果真结束

.如果真 (编辑框2.内容 ＝ “”)
信息框 (“请输入您的密码！”, #错误图标, )
编辑框2.获取焦点 ()
返回 ()
.如果真结束
用户名 ＝ 编辑框1.内容
到首记录 ()
.如果 (查找 (读 (“用户名”) ＝ 用户名))
密码 ＝ 取数据摘要 (到字节集 (编辑框2.内容))
.如果真 (读 (“密码”) ≠ 密码)
信息框 (“密码错误！”, #错误图标, )
编辑框2.获取焦点 ()
返回 ()
.如果真结束
信息框 (“成功登录！”, 0, )
.否则
信息框 (“帐号不存在！”, #错误图标, )
编辑框1.获取焦点 ()
返回 ()
.如果结束

.子程序 _按钮2_被单击, , , 注册
.局部变量 用户名, 文本型
.局部变量 密码, 文本型

用户名 ＝ 删全部空 (编辑框1.内容)
.如果真 (用户名 ＝ “”)
信息框 (“请输入要注册的帐号！”, #错误图标, )
编辑框1.获取焦点 ()
返回 ()
.如果真结束

.如果真 (编辑框2.内容 ＝ “”)
信息框 (“请输入要注册的密码！”, #错误图标, )
编辑框2.获取焦点 ()
返回 ()
.如果真结束
到首记录 ()
.如果真 (查找 (读 (“用户名”) ＝ 用户名))
信息框 (“注册的帐号已存在！”, #错误图标, )
编辑框1.获取焦点 ()
返回 ()
.如果真结束
密码 ＝ 取数据摘要 (到字节集 (编辑框2.内容))
.如果 (加记录 (用户名, 密码))
信息框 (“成功注册！”, 0, )
.否则
信息框 (“注册失败！”, 0, )
.如果结束