Question

批处理备份当天生成文件夹

查找一个目录中当天生成的文件夹，并且copy出来

Answer 1

@echo off
cd.>tmp.txt
set "dst=e:\bak\"
echo 查找当前目录下%date:~0,10%创建的文件夹并复制到%dst%
setlocal enabledelayedexpansion
for /f "tokens=1-3*" %%i in ('dir /ad /tc^|findstr ":"') do (
set var=%%i%%j%%k%%l
if "!var:~1,1!"==":" set route=!var!
if "%%i"=="%date:~0,10%" (
if not "!route!"=="!var!" (
if not "%%j"=="" (
if not "%%l"=="." (
if not "%%l"==".." (
echo %%l>>tmp.txt
)))))
)
findstr .* tmp.txt>nul||(echo 未找到%date:~0,10%创建的文件夹&pause&del tmp.txt&exit /b)
for /f "delims=" %%a in (tmp.txt) do xcopy "%%a" "!dst!%%a\" /ye
pause&del tmp.txt&exit /b

追问

NB，大神啊，请再指点如果想要搜索某个特定目录下的文件夹（比如d:\test\）应该在哪句把这个目录添加进去？

追答

第一句@echo off下面加入以下：
set "soure=%~dp0"
set /p soure=输入路径，回车默认当前目录:
cd /d %soure%||(pause&exit /b)

追问

您好，请问如果我想要搜索一个网络路径如（\\192.168.6.2\test)应该如何操作，您的程序把我上面的功能都实现了，但是我更改了一下其中的“set /p soure=输入路径，回车默认当前目录：”为“set soure=\\192.168.6.2\test ”后运行提示“CMD 不支持将 UNC 路径作为当前目录”，请再帮忙修改一下好么，谢谢

追答

@echo off
setlocal enabledelayedexpansion
set "soure=%~dp0"
set /p soure=输入路径，回车默认当前目录:
if "!soure:~0,2!"=="\\" (
echo 当前格式为网络路径，请保证双方已开启共享。
set /p netuser=输入连接!soure!的用户名：
set /p netps=输入连接!soure!的密码：
net use z: !soure! "!netps!" /user:"!netuser!"
set "soure=z:"
)
cd /d !soure!||(pause&exit /b)
cd.>%~dp0tmp.txt
set "dst=e:\bak\"
echo 查找!soure!目录下%date:~0,10%创建的文件夹并复制到!dst!
for /f "tokens=1-3*" %%i in ('dir /ad /tc^|findstr ":"') do (
set var=%%i%%j%%k%%l
if "!var:~1,1!"==":" set route=!var!
if "%%i"=="%date:~0,10%" (
if not "!route!"=="!var!" (
if not "%%j"=="" (
if not "%%l"=="." (
if not "%%l"==".." (
echo %%l>>%~dp0tmp.txt
)))))
)
findstr .* %~dp0tmp.txt>nul||(echo 未找到%date:~0,10%创建的文件夹&goto :end)
for /f "delims=" %%a in (%~dp0tmp.txt) do xcopy "%%a" "!dst!%%a\" /ye
:end
pause&del %~dp0tmp.txt&net use z: /delete /y 2>nul&exit /b

追问

您好，运行后效果如图，请问是什么原因

追答

别放在有空格路径的地方执行，如桌面