Question

vb编的应用程序，可以在第一次执行时改变它的属性，以后再启动的时候就用新的属性？

比如说：combo控件，list下有1，2，3，4，5，5行内容，本来默认combo.text是1。程序执行中，想把text属性改为2，以后启动时候直接显示在combo控件里。这个要怎么弄？

Answer 1

要记住的项目少的话可以写到注册表里，下次取出就行。
多的话可以加个配置文件，从配置文件中取出

追问

这个配置文件要怎么弄呢？

追答

把以下代码保存到模块中，就是bas文件，然后直接调用
Option Explicit

Declare Function GetPrivateProfileStringByKeyName& Lib "kernel32" Alias _
"GetPrivateProfileStringA" (ByVal lpApplicationName$, ByVal lpszKey$, ByVal lpszDefault$, ByVal lpszReturnBuffer$, ByVal cchReturnBuffer&, ByVal lpszFile$)
Declare Function WritePrivateProfileStringByKeyName& Lib "kernel32" Alias _
"WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As String, ByVal lpString As String, ByVal lplFileName As String)
Declare Function MakeSureDirectoryPathExists Lib "imagehlp.dll" (ByVal DirPath As String) As Long
' @(f)
' 功能 : 读取配置文件
' 返回值 : 读取内容
' 参数 : ARG1 - 读取的段落
' : ARG2 - 读取的关键字
' : ARG3 - 读取的文件名
' 功能说明 : 从配置文件中读取指定内容。
' 备注 :
Function ReadIni(strFileSection As String, strKey As String, ByVal filePath As String) As String
Dim strValue As String
Dim lngRetLen As Long
Dim READ_BUFF As Long

READ_BUFF = 1000
strValue = String(READ_BUFF + 1, Space(1))
lngRetLen = GetPrivateProfileStringByKeyName(strFileSection, strKey, "", strValue, READ_BUFF, filePath)
If lngRetLen >= 1 Then
ReadIni = Left(strValue, lngRetLen)
Else
ReadIni = ""
End If
End Function
' @(f)
' 功能 : 写配置文件
' 返回值 : 是否写入
' 参数 : ARG1 - 写入的段落
' : ARG2 - 写入的关键字
' : ARG3 - 写入的内容
' : ARG4 - 写入的文件名
' 功能说明 : 向配置文件指定的位置写入内容。
' 备注 :
Public Function WriteIni(ByVal psection As String, ByVal pkey As String, ByVal pvalue As String, ByVal filePath As String) As Integer
Dim ret As Long
Dim Buff As String * 128
Dim i As Integer

Buff = pvalue + Chr(0)
ret = WritePrivateProfileStringByKeyName(psection, pkey, Buff, filePath)
WriteIni = ret
End Function

追问

把这代码复制到一个模块里，在改变属性时调用writeini函数保存起来。然后在下一次启动时候通过readini读取出来就可以了是吧？能举个例子不？

追答

你得自己加配置文件啊，这是读写配置文件的共通代码。
在你工程下随便建个记事本文件，改名为XXX.ini，格式如下：
[form1]
combo1="2"
combo2="3"
想保存的时候只要
WriteIni("form1","combo1","4",App.Path & "/XXX.ini")

之后文件内容就会变为
[form1]
combo1="4"
combo2="3"
下次启动时再读出：
combo1.text=ReadIni("form1","combo1",App.Path & "/XXX.ini")

追问

哦，我大概懂了。这两个函数可以读取、写入所有控件的所有属性是吧？

追答

那就看你用多少了，用多少就定义多少呗
[form1]
combo1="2"
这里的form1叫做节，combo1叫做键，这是随便写的，看你怎么方便了，例如也可以这样：
[combo1]
defaultText="2"
[text1]
defaultText="你好"
defaultColor="1"
随你发挥啦

Answer 2

在第一次执行并修改属性后，把修改后的值保存到文本文件、INI文件、注册表或网络中。然后在再次启动时读取这个值并赋值给控件即可。下面是利用注册表的例子：

Private Sub Form_Load()   '程序启动时调入参数
Combo1.ListIndex = Val(GetSetting(App.Title, "setup", "Combo1", 0))
End Sub
Private Sub Form_Unload(Cancel As Integer)   '程序退出时保存参数
SaveSetting App.Title, "setup", "Combo1", CStr(Combo1.ListIndex)
End Sub

Answer 3

每次退出程序时，保存combo控件的选择结果，保存到一个文件，下次运行时先读取文件。

Answer 4

最简单的办法是写入文本文件，然后读取。