Question

批处理 文件夹 文件名

批处理 文件移动 文件重命名

在D盘有个文件夹为[B000801] 不含括号

内含几个图片(需要删除这几个图片)
一个子文件夹 名为[ps] ps里面有几个图片[需要这样处理 原图片名字是杂乱的 需要改为以父文件夹名B000801开头的规律性名字 B000801 (1).jpg B000801 (2).jpg B000801 (3).jpg ... 并且要把这些文件移到父文件夹B000801中 删除ps文件夹]

最终的结果是
父文件夹中只含有ps原来的已经命名好的图片

D盘有几千个这样的文件夹 怎么批量处理呢

先谢谢各位
D盘里面的文件夹名字都是规律性后面数字+1的

B000801
B000802
B000803
B000804
...

Answer 1

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir/b/ad "d:\B00????"') do (
 set "fpath=d:\%%a"
 set "fname=%%a"
 pushd "!fpath!\ps"
 set count=0
 for /f "delims=" %%i in ('dir/b/a-d *.jpg') do (
   set/a count=!count!+1
   echo Moving [%%i]
   call move /Y "!fpath!\ps\%%i" "!fpath!\!fname!^(!count!^).jpg"
 )
 popd
 rd/s/q "!fpath!\ps"
)
echo done.
pause

使用前做好备份.

追问

谢谢先 能逐行解释一下吗 有些参数我要改的

追答

从第2行开始吧:
for循环查找D盘下B00开头总长度为7个字符串的文件夹（不够的部分用?号来补足）
设置一个变量内容为， 比方说：d:\B000801
设置一个变量为文件夹名字， 比方说：B000801
pushd 进入 d:\B000801\ps文件夹内
设置个计数器count=0
在ps文件夹中寻找所有jpg格式的文件，每找到一个count++
用move命令移动这些文件，同时根据count的值来重新命名
路径popd，返回到程序一开始的路径（你批处理所在的地方）
删除 d:\B000801\ps 这个文件夹以及里面的所有文件
继续for循环处理下一个文件，比方说: d:\B000802，然后重新上述步骤

追问

非常感谢啊 非常强大啊 但是还有2个要求忘记实现了 可以帮忙一起实现吗

如上所述咯

B000801文件夹里面除了ps文件夹 还有一些不重要的图片 这些图片也是要删除的 这个删除命令怎么写的 应该加到哪里呢

最后的文件名是 B000801(1).jpg 而我需要的是B000801 (1).jpg
B000801和(1).jpg之间有个空格

希望能很快看到您强大的回复 谢谢先

追答

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir/b/ad "d:\B00????"') do (
set "fpath=d:\%%a"
set "fname=%%a"
pushd "!fpath!\ps"
set count=0
for /f "delims=" %%i in ('dir/b/a-d *.jpg') do (
set/a count=!count!+1
echo Moving [%%i]
call move /Y "!fpath!\ps\%%i" "!fpath!\!fname!^ (!count!^).jpg"
)
popd
rd/s/q "!fpath!\ps"
::这里添加你要删除的东西
echo del abc.jpg
)
echo done.
pause

追问

::这里添加你要删除的东西

这句话 什么意思呢 不懂呀

另外还有个问题 比如D盘里面有多个文件夹 命名分别是1 2 3 4 5 6 7 8 9.... 各自的【子文件夹】名字有的是【ps】【ps过】【已ps】我想统一都改成【PS】 怎么用批处理实现呢

谢谢

追答

就是比方说你在B000xxx文件夹里都会有什么要删的比方说，readme.txt的文件，你就在把 echo del abc.jpg这句换成del readme.txt就好。
第二个功能就再写个批处理了。
从1开始尝试，一直到不存在位置。
@echo off&setlocal enabledelayedexpansion
set index=1
:loop
if exist "%cd%\%index%\" (
pushd "%cd%\%index%"
for /f "delims=" %%a in ('dir/b/ad *.*^| find "ps"') do (
ren "%%a" PS
)
popd
) else (
goto end
)
set/a index+=1
goto loop
:end
echo Done.
pause
exit

追问

不好意思 最近很忙 现在才看到你的回复

我测试过了 我之前说得不清楚

对于第二个问题 如果文件夹名字是 B000801 B000802 B000803 b000804 b000805 B000806...这样一直下去【注意：有时候是B 有时候是b】 文件夹里面的子文件夹名字是不规则的 该怎么统一换成PS呢

追答

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir/b/ad "d:\B00????"') do (
set "fpath=d:\%%a"
pushd "!fpath!"
for /f "delims=" %%i in ('dir/b/ad *.*^| find "ps"') do (
if exist "%%i" (
ren "%%i" PS
)
)
popd
)
echo done.
pause