Question

求一款软件用于列举数字的排列组合，最好能像excel表格那种格式显示出来

比如给出8个数字，选取其中5个进行组合，共有多少种组合，能一一列举出来，最好能由大到小或者由小到大依次排列，功能越多越好。如果Excel能做到也行，但我不知道怎么用，求高手指点，财富值之类的都小事儿，你要喜欢咱都给你

Answer 1

给你一段VBA代码吧，放入EXCEL的代码页中（ALT+F11），运行主程序MYCMB()就会把结果输出到表格中。

Sub MYCMB()
Const t = 5, Z = 8 '从8个数字中取5个进行组合
Dim CNO, q(), CM(), CM2()
st = Timer
'为保证速度，用数组存储结果
ReDim q(1 To t)
ReDim CM(1 To WorksheetFunction.combin(Z, t))
nq 1, 1, t, Z, CNO, q(), CM()

'转二维数组，以便EXCEL存放
ReDim CM2(1 To CNO, 1 To t)
For i = 1 To CNO
For j = 1 To t
CM2(i, j) = CM(i)(j)
Next j
Next i
'输出结果到表格
Cells(1, t + 2) = "组合数"
Cells(1, t + 3) = CNO
If CNO > 65536 Then CNO = 65536
Range(Cells(1, 1), Cells(CNO, t)) = CM2
Cells(2, t + 2) = "运行时间(秒)"
Cells(2, t + 3) = Timer - st
End Sub
'递归函数
Sub nq(n, s, x, E, CNO, q(), CM())
For i = s To E - x + n
q(n) = i
If n = x Then '当前组合的数字已经选完
CNO = CNO + 1
CM(CNO) = q
Else
nq n + 1, i + 1, x, E, CNO, q(), CM()
End If
Next i
End Sub

追问

虽然懂程序，但没用过这个，请具体指点怎么操作，我要把16个数字按5位组合，不连续的16个数，谢谢

追答

16个数字？是包括两位数十进制数字，还是十六个十六进制数字？是16个数字选5个进行组合吗？那就不一定是5位数了？能否说明白一点，最好有举例说明你的要求。

追问

都是十进制数字比如：1；3；4；5；9；10；11；13；17；19；25；28；29；32；34；39；组合1 3 4 5 9,1 3 4 5 10,1 3 4 5 11,1 3 4 5 13......依次排列下去，会有4368种组合，在excel表中一一列举出来

追答

直接把第一行的参数改一下就可以实际1到16这十六个数字选5，Const t = 5, Z = 16
但如果要指定数字或其它字符串名称，则需要增加一个存放这此字符串名称的数组。如下：

Sub MYCMB()
Dim Z, t '从Z个元素中取出t个进行组合
Dim CNO, q(), CM(), CM2(), ID
st = Timer
'设置元素名称，及要取出元素的个数
ID = Array("1", "3", "4", "5", "9", "10", "11", "13", "17", "19", "25", "28", "29", "32", "34", "39")
Z = UBound(ID) + 1 '总的元素个数
t = 5 '要取的元素个数
'为保证速度，用数组存储结果
ReDim q(1 To t)
ReDim CM(1 To WorksheetFunction.combin(Z, t))
nq 1, 1, t, Z, CNO, q(), CM(), ID

'转二维数组，以便EXCEL存放
ReDim CM2(1 To CNO, 1 To t)
For i = 1 To CNO
For j = 1 To t
CM2(i, j) = CM(i)(j)
Next j
Next i
'输出结果到表格
Cells(1, t + 2) = "组合数"
Cells(1, t + 3) = CNO
If CNO > 65536 Then CNO = 65536
Range(Cells(1, 1), Cells(CNO, t)) = CM2
Cells(2, t + 2) = "运行时间(秒)"
Cells(2, t + 3) = Timer - st
End Sub
'递归函数
'n,s:当前组合中位置、当前要选的数的开始
'e和x：从e个数里取x个进行组合
'CNO：组合数
'CM()：组合结果
Sub nq(n, s, x, E, CNO, q(), CM(), ID)
For i = s To E - x + n
q(n) = ID(i - 1)
If n = x Then '当前组合的数字已经选完
CNO = CNO + 1
'ReDim Preserve CM(1 To CNO)
CM(CNO) = q
Else
nq n + 1, i + 1, x, E, CNO, q(), CM(), ID
End If
Next i
End Sub

追问

哈哈哈，刚才没刷新网页，要的就是这个，非常感谢.....100分你的了

追答

做了个完整的带界面的，排列和组合都可以做。见附件！