Question

一个excel里有sheet1到sheet10，如何用宏来实现：点击按钮将sheet2到sheet

一个excel里有sheet1到sheet10，如何用宏来实现：点击按钮将sheet2到sheet5分别另存为单独的excel工作簿，且将其中公式转化成文本或数值，新excel以各自的工作表名命名，如sheet2另存的excel命名为“sheet2”。保存路径为原excel所在路径。

Answer 1

方法太笨
等巧方法

Sub 复制工作表()
For i = 2 To 5
ThisWorkbook.Sheets("Sheet" & i).Copy
Set bok = ActiveWorkbook
bok.Sheets(1).Cells.Copy
bok.Sheets(1).Cells.PasteSpecial Paste:=xlPasteValues
bok.SaveAs ThisWorkbook.Path & "\" & "Sheet" & i & ".xlsx"
bok.Close
Next i
End Sub

追问

你写的也很好，好想也给你分。

只能再次谢谢你了

Answer 2

Sub 工作表拆分()

Dim sht As Worksheet
Application.ScreenUpdating = False
Application.DisplayAlerts = False

'以下是拆分工作表

For Each sht In Sheets
sht.Copy
ActiveWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\" & sht.Name & ".xls"

'以下是转为数值

ActiveWorkbook.ActiveSheet.Cells.Copy
ActiveWorkbook.ActiveSheet.Range("A1").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
'完成
ActiveWorkbook.Close
Next
Application.DisplayAlerts = True
Application.ScreenUpdating = True

End Sub

Answer 3

这个问题不是太复杂,先Mark一下,稍后上代码和附件.

追问

哎，真羡慕你们这些会vba编程的高手

追答

Alt+F11打开VBE编辑窗口,插入--模块,复制粘贴代码,F5运行.

Sub Sheets2Workbooks()
    Dim i As Integer, iPath As String
    Const iStart = 2 '开始工作表
    Const iEnd = 5 '结束工作表
    iPath = ThisWorkbook.Path & "\" '保存路径
    Application.ScreenUpdating = False '关闭屏幕更新
    If Sheets.Count < iStart Or Sheets.Count < iEnd Then MsgBox "error": Exit Sub '如果工作表总数小于开始工作表或结束工作表,报错后退出
    For i = iStart To iEnd '开始工作表到结束工作表之间循环
        Sheets(i).Copy '复制工作表
        ActiveSheet.Cells.Copy '复制全部单元格
        With Range("A1")
            .PasteSpecial Paste:=xlPasteValues '值粘贴
            .Select '选中A1单元格
        End With
        Application.CutCopyMode = False '取消复制模式
        With ActiveWorkbook
            .SaveAs Filename:=iPath & ActiveSheet.Name & ".xlsx", FileFormat:=xlOpenXMLWorkbook '保存工作簿
            .Close '关闭工作簿
        End With
    Next
    Application.ScreenUpdating = True '恢复屏幕更新
    MsgBox "Done!" '提示完成
End Sub

示例文件如下,单击按钮后运行.

追问

如果我的工作表改名字，比如sheet2叫“个税”，sheet3叫“印花税”，sheet4叫“营业税”，sheet5叫“所得税”，该怎么修改您的代码

另外，我是建了一个按钮，然后编辑宏来实现的。是不是把头sub和尾end sub删掉？

追答

工作表的名字不影响结果，代码中根据工作表的排列顺序运行

可以插入一个图形，然后指定宏就可以了。或者新建按钮后双击按钮，复制粘贴sub和end sub之间的内容

追问

不知道那里出问题了

追答

Book1没有保存，thisworkbook.path为空值，所以程序报错。建议先保存文件

追问

不好意思，还的继续请教您，粘贴数值提次操作要求合并单元格具有相同的大小，这有办法解决吗？

原表中确实有很多合并单元格

能不能先正常粘贴，把格式也贴过去，然后再贴一遍值

追答

.PasteSpecial Paste:=xlPasteValues的下面加上一行 .PasteSpecial Paste:=xlPasteFormats