Question

vb中怎样做出时钟?

用到circle,line和timer 控件,做出一个会动的时钟,请问要怎么做?
很遗憾,我用的是vb6.0 中文企业版

Answer 1

VB可使用Timer控件、Line控件和绘图或加载图片等制作指针式时钟。

• Timer 控件，通过引发 Timer 事件，Timer 控件可以有规律地隔一段时间执行一次代码。

• Line 控件，Line 控件是图形控件，它显示水平线、垂直线或者对角线。

  运行时不能使用 Move 方法移动 Line 控件，但是可以通过改变 X1、X2、Y1 和 Y2
  属性来移动它或者调整它的大小。

• Circle 方法，在对象上画圆、椭圆或弧。

  以下是通过加载图片的指针式时钟代码：

Option Explicit
    Private Const PI = 3.1415926
    Dim X(1) As Single, Y(1) As Single
    Dim OriAngle As Single, DestAngle As Single, r As Single
Private Sub RotateLine(objL As Line, bsPointX As Single, bsPointY As Single, RotateAngle As Single)
    With objL
        X(0) = .X1
        Y(0) = .Y1
        X(1) = .X2
        Y(1) = .Y2
    End With
    Dim i As Integer
    For i = 0 To 1
        If X(i) - bsPointX <> 0 Then
            OriAngle = Atn((Y(i) - bsPointY) / (X(i) - bsPointX))
        Else
            OriAngle = IIf(Y(i) > bsPointY, PI / 2, 1.5 * PI)
        End If
            If X(i) - bsPointX < 0 Then
                If OriAngle < 0 Then
                    OriAngle = PI - Abs(OriAngle)
                Else
                    OriAngle = PI + Abs(OriAngle)
                End If
            End If
            DestAngle = OriAngle + RotateAngle
            r = Sqr((X(i) - bsPointX) ^ 2 + (Y(i) - bsPointY) ^ 2)
            X(i) = bsPointX + r * Cos(DestAngle)
            Y(i) = bsPointY + r * Sin(DestAngle)
    Next i
    With objL
        .X1 = X(0)
        .Y1 = Y(0)
        .X2 = X(1)
        .Y2 = Y(1)
    End With
End Sub
Private Sub Form_Load()
    Timer1.Interval = 1000
    Dim i As Long
    For i = 1 To Val(Mid(Time$, 7, 2))
        RotateLine Line3, Line3.X1, Line3.Y1, 1 * PI / 30
    Next
    For i = 1 To Val(Mid(Time$, 4, 2))
        RotateLine Line2, Line2.X1, Line2.Y1, 1 * PI / 30
    Next
    For i = 1 To Val(Mid(Time$, 1, 2)) * 5 '对时针
        RotateLine Line1, Line1.X1, Line1.Y1, 1 * PI / 30
    Next
    For i = 1 To Val(Mid(Time$, 4, 2)) '对时针
        RotateLine Line1, Line1.X1, Line1.Y1, 1 * PI / 360
    Next
End Sub
Private Sub Timer1_Timer()
    RotateLine Line3, Line3.X1, Line3.Y1, 1 * PI / 30
        RotateLine Line2, Line2.X1, Line2.Y1, PI / 1800
    If Mid(Time$, 7, 2) = "00" Or Mid(Time$, 7, 2) = "30" Then
        RotateLine Line1, Line1.X1, Line1.Y1, 1 * PI / 720
    End If
    Me.Caption = Time$
End Sub

Answer 2

'Timer1的Interval属性设为1000
'建议Form1的Width属性设为2595，Height属性设为2535

Dim a As Integer, b As Integer, rad As Double
Private Sub Form_Load()
a = Me.ScaleWidth \ 2 '圆心X坐标
b = Me.ScaleHeight \ 2 '圆心Y坐标
rad = Atn(1) / 45 '1角度的弧度数
Me.DrawWidth = 2
End Sub

Private Sub Timer1_Timer()
Dim angle1 As Double, angle2 As Double, angle3 As Double
angle1 = ((Hour(Now) Mod 12) * 30 + Minute(Now) / 2 - 90) * rad '时针的角度
angle2 = (Minute(Now) * 6 + Second(Now) / 10 - 90) * rad '分针的角度
angle3 = (Second(Now) * 6 - 90) * rad '秒针的角度
Cls '清除画面，以便画下一秒的状态
Me.Circle (a, b), 720 '画石英钟轮廓
For i = 1 To 12
Me.CurrentX = a - IIf(i < 7, 115, 170) + 600 * Cos((i * 30 - 90) * rad) '刻度X坐标
Me.CurrentY = b - 90 + 600 * Sin((i * 30 - 90) * rad) '刻度Y坐标
Print i '画刻度
Next
Me.Line (a, b)-(a + 300 * Cos(angle1), b + 250 * Sin(angle1)), vbBlue '画时针
Me.Line (a, b)-(a + 400 * Cos(angle2), b + 550 * Sin(angle2)), vbBlue '画分针
Me.Line (a, b)-(a + 600 * Cos(angle3), b + 600 * Sin(angle3)), vbRed '画秒针
End Sub

Answer 3

请问你是用VB2005吗?如果用VB2005做这个题非常地简单.
在窗体是用label1设置一个label1.text框.然后双击label1,进入代码编辑器,在这里输入label1.text=timestring
label1.text=now()'这是VB6.0的
就可以实现一个会走的时钟啦.
如果同时还想实现日期功能,就把上面的代码改成label1.text=datestring
那个timer控件的属性就这样设置
timer1.enabled=true
timer1.interval=1000
这样就可以了.
到时你们可能还会做一个关于倒计时器的程序,这可就没有像时钟这样简单咯,具体做法我的空间有,你可以看一下吧.