Question

asp 时间格式问题

时间是用now（）获得的，我现在要以11/27 00:17这样的格式输出，不一定是这样。只要输出月日，还有时分就行了
怎么做？

Answer 1

<%=Format_Time(now(), 8)%></br>

<%
Function Format_Time(s_Time, n_Flag)
'******************************************************
'　作用：格式化时间(显示)。
'　参数：二个，一个是时间，另外一个是格式化的参数，也就是要用那种形式参数：n_Flag
' 1:"yyyy-mm-dd hh:mm:ss"
' 2:"yyyy-mm-dd"
' 3:"hh:mm:ss"
' 4:"yyyy年mm月dd日"
' 5:"yyyymmdd"
' 6:"yyyymmddhhmmss"
' 7:"yyyymmddhhmm"
' 8:"mm月dd日
' 9:dd日
'　返回：相应的日期格式
'　注意：调用时要注意，使用本函数的相关返回值.
'******************************************************
Dim y, m, d, h, mi, s
Format_Time = ""
If IsDate(s_Time) = False Then Exit Function
y = cstr(year(s_Time))
m = cstr(month(s_Time))
If len(m) = 1 Then m = "0" & m
d = cstr(day(s_Time))
If len(d) = 1 Then d = "0" & d
h = cstr(hour(s_Time))
If len(h) = 1 Then h = "0" & h
mi = cstr(minute(s_Time))
If len(mi) = 1 Then mi = "0" & mi
s = cstr(second(s_Time))
If len(s) = 1 Then s = "0" & s
Select Case n_Flag
Case 1
' yyyy-mm-dd hh:mm:ss
Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
Case 2
' yyyy-mm-dd
Format_Time = y & "-" & m & "-" & d
Case 3
' hh:mm:ss
Format_Time = h & ":" & mi & ":" & s
Case 4
' yyyy年mm月dd日
Format_Time = y & "年" & m & "月" & d & "日"
case 5
'yyyymmdd
Format_time= y&m&d
case 6
'yyyymmddhhmmss
Format_time=y&m&d&h&mi&s
case 7
'yyyymmddhhmm
Format_time=y&m&d&h&mi
case 8
Format_time=m & "月" & d & "日"
case 9
Format_time=d & "日"
End Select
End Function
%>

Answer 2

now() 获取当前系统日期和时间,ASP输出可以这样写：<%=now()%>
Year(now()) 获取年份， ASP输出：<%=Year(now())%>
Month(now()) 获取当前月份，ASP输出：<%=Month(now())%>
day(now()) 获取当天数，ASP输出：<%=day(now())%>
Minute(now()) 获取分钟数，ASP输出：<%=Minute(now())%>
Second(now()) 获取秒钟数，ASP输出：<%=Second(now())%>