Question

用批处理怎样编写一个用if判断的批处理：执行后判断能 ping 192.168.1.1 就运行d：

用批处理怎样编写一个用if判断的批处理：执行后判断能 ping 192.168.1.1 就运行d：/2013qq ，不通就提示（网络故障，请检查网络）

Answer 1

不知道是否还有其它的要求？ 比如是否还保留运行的命令行窗口？ 如果没有，可以这样写：

@echo off

set "ip=192.168.1.1"
set "app=d:\2013qq"
set "errmsg=Network error, please check the connection."

echo.Ping in progress....
ping %ip% 1>nul 2>nul
if ERRORLEVEL 1 (
echo %errmsg%
) else (
echo start "%app%"
)

@echo on

ip，app和errmsg都可以自定义。 测试通过后， 把echo start里面的echo删除，就可以运行程序了。

追问

感谢您，要求就 如果通就关闭窗口，不通就一直在此提示界面

追答

那么把

echo start "%app%"

这句改成

echo start "%app%" & exit

即可。

注： 还是那句话，测试通过，把上面那句的echo去除。

追问

感谢您，我用电脑上时再试试，不行在请教您

追答

希望能帮到你。

你说的“提示界面”，是指不停重复ping，还是退出bat，但保留命令行窗口？ 如果是ping界面，那么是否有间隔要求？ 如果是，参数又是多少？

追问

就是ping不通就停留在(网络故障，请检查网络)这个提示，同时也一直ping，知道网络弄好了，ping通了就直接运行qq在关闭批处理窗口

追答

修改后的代码如下：

@echo off

set "ip=192.168.1.1"
set "app=d:\2013qq"
set "errmsg=Network error, please check the connection."
:: interval between each try, in millisecond.
set /a w_int=60000
:: maximum try out count times
set /a t_cnt=30
:: iterator, initializing to 1
set /a iter=1

:repeat
if {%iter%}=={%t_cnt%} echo Maximum tryout has reached. & goto end
echo.Ping in progress.... %iter%/%t_cnt%
ping %ip% 1>nul 2>nul
if ERRORLEVEL 1 (
echo %errmsg%
) else (
echo start "%app%" & exit
)
ping 1.1.1.1 -n 1 -w %w_int% >nul
set /a iter+=1
goto repeat

:end
@echo on

缺省参数：每次的间隔1分钟（60000毫秒）；一共尝试30次，之后如果网络还不通，程序退出。

Answer 2

@PING 192.168.1.1 > NUL && START "" "D:\QQ.exe" || ECHO 连接失败... && PAUSE

追问

感谢您