Question

各位谁能帮我解释下道路ansys命令流的几个问题，主要是数字为什么是这个。麻烦啦！初学者，需要帮忙谢啦

FINISH
/CLEAR, START
*set, d, 2
/prep7
et,1,solid45
mp,ex,1,30e9
mp,prxy,1,0.15
mp,ex,2,1500e6
mp,prxy,2,0.2
mp,ex,3,1500e6
mp,prxy,3,0.25
mp,ex,4,600e6
mp,prxy,4,0.35
mp,ex,5,40e6
mp,prxy,5,0.35
K, 1,-5/2-d,-3.5/2-d,0
K, 2,-5/2-d,3.5/2+d,0
K, 3, 5/2+d, 3.5/2+d,0
K, 4, 5/2+d,-3.5/2-d,0
A, 1,2,3,4
voffst,1,3.66,0（3.66是各层和？还是什么）
wpoffs,0,0,-0.21
vsbw,all
wpoffs,0,0,-0.2
vsbw,all
wpoffs,0,0,-0.25
vsbw,all
wpoffs,0,0,0.65（这里为什么是正值）
wpoffs,-5/2,0,0
wprota,0,0,90（为什么这里z轴要旋转90度？—）
vsbw,all
wpoffs,0,0,5
vsbw,all
wprota,0,90,0
wpoffs,0,0,1.75
vsbw,all
wpoffs,0,0,-3.5
vsbw,all
asel,s,loc,z,0
asel,r,loc,x,-5/2,5/2
asel,r,loc,y,-3.5/2,3.5/2
vext,all,,,0,0,0.25
allsel
vplot
lsel,s,loc,z,-0.66,-3.66
lsel,r,length,,2.5
lesize,all,0.5
lsel,s,loc,z,-0.41,-0.66
lsel,r,length,,0.25
lesize,all,0.1
lsel,s,loc,z,-0.2,-0.41
lsel,r,length,,0.2
lesize,all,0.1
lsel,s,loc,z,0,-0.2
lsel,r,length,,0.2
lesize,all,0.05
lsel,s,loc,z,0.25,0
lsel,r,length,,0.25
lesize,all,0.05
lsel,s,loc,z,0.25,-3.66
lsel,r,loc,y,-3.5/2-d, 3.5/2+d
lsel,r,loc,x,-5/2, 5/2
lsel,r,length,,5
lesize,all,0.1
lsel,s,loc,z,0.25,-3.66
lsel,r,loc,x,-5/2-d, 5/2+d
lsel,r,loc,y,-3.5/2, 3.5/2
lsel,r,length,,3.5
lesize,all,0.1
lsel,s,loc,z,0.25,-3.66
lsel,r,length,,d
lesize,all,0.4
vsel,s,loc,z,0,0.25
vplot
type,1
mat,1
vmesh,all
vsel,s,loc,z,0,-0.21
vplot
type,1
mat,2
vmesh,all
vsel,s,loc,z,-0.21,-0.41
vplot
type,1
mat,3
vmesh,all
vsel,s,loc,z,-0.41,-0.66
vplot
type,1
mat,4
vmesh,all
vsel,s,loc,z,-0.66,-3.66
vplot
type,1
mat,5
vmesh,all
nsel,s,,,all
nsel,s,loc,z,-3.66
d,all,all,0
谢啦

Answer 1

voffst,1,3.66,0（3.66是各层和？还是什么）：根据命令流的输入来看，是除了模型中突出的部分的所有土层的和；

wpoffs,0,0,0.65（这里为什么是正值）：wp移动时x、y、z方向是累加的，向z的负方向移动了总计0.66，这是应该是回到z向-0.01的位置；
wprota,0,0,90（为什么这里z轴要旋转90度？）：采用vsbw时，体切割通过workplan，wp默认切割面为x-y平面，当你切割方向发生变化就要将x-y面转到需切割方向上去。