Question

求魔兽世界MS各种宏、有的贴上。尽量详细点谢谢

尽量详细、本人玩暗影和神圣。

Answer 1

1.漂浮术
#showtooltip
/cast [mod:alt,target=player][raid]漂浮术;[harm,target=player]漂浮术;[target=player]漂浮术
没组队的情况下，没有目标或目标敌对则对自己施放；在队伍或团队中，目标是队友则施放给目标，否则施放给自己。
说的有点麻烦，其实防止选择其他目标后狂点漂浮也施放不出来最后摔死的事故发生。。。

2.恢复，痛
#showtooltip [mod:alt][help]恢复;[harm]暗言术：痛;暗言术：痛
/cast [mod:alt,target=player][help]恢复;[harm]暗言术：痛
目标友善，则施放恢复；目标敌对，则施放痛，任何情况下按alt，都是对自己施放恢复。

3.心灵震爆，快速治疗
#showtooltip [mod:alt][help]快速治疗;[spec:1,harm]心灵震爆;[spec:1]心灵震爆;[spec:2,harm]神圣之火;[spec:2]神圣之火
/use [harm,nomod]10
/cast [mod:alt,target=player][help]快速治疗;[spec:1,harm]心灵震爆;[spec:2,harm]神圣之火
原理同宏2，略作修改。
在主天赋(暗影)情况下，目标敌对，则施放心灵震爆，友善则施放快速治疗。
副天赋(戒律)情况下，目标敌对则施放神圣之火，友善则施放快速治疗
/use [harm,nomod]10 这个是工程的火箭手套，编到这里cd就用的，不是工程的可以删掉这行。

4.群体驱散
#showtooltip 群体驱散
/stopcasting
/cast !群体驱散
不多说了，基本都在用，打断当前施法立即释放群体驱散，如果正在施放群体驱散则不打断。

5.驱除疾病，噬灵疫病
#showtooltip [mod:alt][help]驱除疾病;[harm]噬灵疫病;噬灵疫病
/cast [mod:alt,target=player][help]驱除疾病;[harm]噬灵疫病
同宏2，目标敌对则施放噬灵疫病，友善则施放驱除疾病，按alt自我施放驱除疾病。

6.愈合祷言，灭
#showtooltip [mod:alt][help]愈合祷言;[harm]暗言术：灭;暗言术：灭
/cast [mod:alt,target=player][help]愈合祷言;[harm]暗言术：灭
同宏2，目标敌对则施放灭，友善则施放愈合祷言，按alt自我施放愈合祷言。

7.绷带
/use [mod:alt,target=player]厚霜纹布绷带;[harm,target=player]厚霜纹布绷带;[target=player]厚霜纹布绷带
无目标或目标敌对，对自己绷带；目标友善，则绷带目标；alt自我施法。

8.buff宏(以韧为例)
#showtooltip [mod:shift]坚韧祷言;真言术：韧
/cast [mod:shift]坚韧祷言;[mod:alt,target=player][help][target=player]真言术：韧
无目标或目标敌对，则对自己施放最高级韧，目标友善则对目标施放；按住shift则改为施放坚韧祷言。
另外两个buff对应的改一下技能名字就可以。

9.治疗祷言
/use [mod:alt,target=player][help]治疗祷言;[harm,target=player]治疗祷言;[target=player]治疗祷言
无目标或目标敌对，则以自己为目标施放治疗祷言，有目标则对目标施放，alt自我施法。
顺路吐槽暴雪这个技能改的太烦人了。。。

10.联结治疗，法力燃烧
#showtooltip [help]联结治疗;[harm]法力燃烧;法力燃烧
/cast [help]联结治疗;[harm]法力燃烧
同宏2，不多说了。。。。。。打字好累。

11.消散
#showtooltip 消散
/cancelaura 消散
/cast 消散
按一次消散，再按取消。(不适合狂按键盘类玩家)。

12.反恐
#showtooltip 防护恐惧结界
/cast [mod:alt,target=player][help][target=player]防护恐惧结界
同宏2。。。。。。

13.神圣赞美诗
#showtooltip 神圣赞美诗
/cast 心灵专注
/cast 神圣赞美诗
绑一起觉得还是比较合理的。不喜欢的可以不用

14.心灵之火，吸血鬼的拥抱
/castsequence reset=5 心灵之火,吸血鬼的拥抱
嗯嗯，自从3.3暗牧崛起之后，就用了这个宏，点一下施放心灵之火，图标变成吸血鬼拥抱，再点就是施放吸血鬼拥抱啦，5秒之内不做动作复原
都是自身buff技能，绑一起可以节省技能栏~

Answer 2

/cast [target=mouseover,nodead,exists] 法术名称;法术名称
简单的鼠标指向宏,鼠标箭头划过GRID血条即可施放.
绑定在键盘上顺手的位置,适合瞬发类.