Question

批处理怎么比较文件最后修改时间和当前时间？

要写个批处理，获取指定文件的最后修改时间，并和当前时间比较，如果最后修改时间在30分钟之前，要输出一个警告信息。

Answer 1

没那么简单判断分钟就能解决的，如果跨小时，跨天，月，年呢？

@echo off&setlocal enabledelayedexpansion
set "fn=e:\123\abc\a1.txt"
:loop
for %%a in ("%fn%") do (
  if exist "%fn%" (
    for /f "tokens=1-10 delims=/-: " %%i in ("%%~ta !date:~,10! !time:~,5!") do (
      set/a y1=%%i,m1=1%%j%%100,d1=1%%k%%100,h1=1%%l%%100,f1=1%%m%%100,y2=%%n,m2=1%%o%%100,d2=1%%p%%100,h2=1%%q%%100,f2=1%%r%%100
      set /a "f=(1461*(y2+(m2-14)/12)/4+367*(m2-2-(m2-14)/12*12)/12-3*((y2+(m2-14)/12)/100+1)/4-1461*(y1+(m1-14)/12)/4-367*(m1-2-(m1-14)/12*12)/12+3*((y1+(m1-14)/12)/100+1)/4-d1+d2)*1440+(h2-h1)*60+f2-f1"
      if !f! geq 30 (
      	echo 当前时间:【!date:~,10! !time:~,5!】距离上次修改时间:【%%~ta】已过半个小时
      	echo 其它超过30分钟需要运行的代码加在这里...
      )
    )
  )
)
rem 延迟大约30秒后再次判断
ping /n 30 127.1 >nul
goto :loop

Answer 2

@ECHO OFF
REM 获取文件修改时间
SETLOCAL ENABLEDELAYEDEXPANSION
for /f "skip=1 tokens=1,3,5 delims=. " %%a in ('wmic datafile where name^="R:\\Test22\\新建文本文档.txt" get LastModified') do (
IF %%a LSS 0 GOTO end
set a=%%a
SET /a b=%time:~3,2%-!a:~10,2!
IF !b! lss 0 (SET /a b=%time:~3,2%+60-!a:~10,2!)
IF !b! gtr 30 ECHO !b! 文件修改时间在30分钟前
)
:end
PAUSE

假设指定的文件为 新建文本文档.txt.

追问

直接复制你的代码，改了下文件名，运行起来不管什么文件都是“请按任意键继续”

追答

额 那是因为比较文件时间后小于40分钟,所不显示,你需要找个修改时间和系统时间相差30分钟的文件.

@ECHO OFF
REM 获取文件修改时间
SETLOCAL ENABLEDELAYEDEXPANSION
for /f "skip=1 tokens=1,3,5 delims=. " %%a in ('wmic datafile where name^="R:\\Test22\\新建文本文档.txt" get LastModified') do (
IF %%a LSS 0 GOTO end
set a=%%a
SET /a b=%time:~3,2%-!a:~10,2!
IF !b! lss 0 (SET /a b=%time:~3,2%+60-!a:~10,2!)
IF !b! gtr 30 ECHO !b! 文件修改时间在30分钟前
echo 和当前系统相差!b!分钟
)
:end
PAUSE

追问

用你最新的代码测试，对分钟判断是准的，对小时就有点问题。比如1小时30分前的文件，就只能识别出30分钟。不过如果能一直重复执行，对我来说就无所谓，怎么让这个一直重复执行，一发现超过30分钟就提示呢？

追答

额 这个我本来就没写那么多判断,因为不知道你的具体用途,所以把代码尽量精简了.只判断分钟.

追问

哦，我的完整用途：一直重复读取某个文本文件的最后修改时间，如果30分钟内文件没有被修改，就中止指定进程，重启被中止的程序。

追答

@ECHO OFF
REM 获取文件修改时间
SETLOCAL ENABLEDELAYEDEXPANSION
:loop
for /f "skip=1 tokens=1 delims=. " %%a in ('wmic datafile where name^="R:\\Test22\\新建文本文档.txt" get LastModified') do (
IF %%a LSS 0 GOTO end
set a=%%a
SET /a h=%time:~0,2%-!a:~8,2!
SET /a m=%time:~3,2%-!a:~10,2!
IF !h! gtr 0 (IF !m! leq 0 (SET /a h=!h!-1&SET /a m=%time:~3,2%+60-!a:~10,2!)) 
IF !m! gtr 30 (ECHO !h!!m! 文件修改时间在30分钟前) 
)
:END
REM 延时3秒
ping -n 4 127.1>nul
GOTO loop
PAUSE

加了延时和循环,修正1小时30分错误

Answer 3

@echo off
set file="d:\1.txt"
for /f "tokens=1,2" %%i in ('dir /tw %file%^|find "/"') do for /f %%k in (
'^>"%tmp%\_tmp.vbs" echo,wscript.echo datediff("n"^,"%%i %%j"^,"%date:~0,10% %time:~0,8%"^)^&^&cscript //nologo "%tmp%\_tmp.vbs"^&^&del /f /a /q "%tmp%\_tmp.vbs"'
) do if %%k gtr 30 echo 警告！最后修改时间在%%k分钟之前...
pause