Question

魔兽世界深冰法师的宏命令如何设置?

高手进 谢谢

Answer 1

朋友 冰法的宏有很多的
一 ：几个比较简单的宏
1：气定冰箭宏。
从核蛋宏转化而来。如果需要开某个饰品则加入一行 例如： /use 银色新月徽记 或者/use 13 /use 14 13和14分别指人物当前装备的上下2个饰品。

#showtooltip 寒冰箭(等级 13)
/stopcasting
/cast 冰冷血脉
/cast 奥术强化
/cast 气定神闲
/cast 寒冰箭(等级 13)

[::艾泽拉斯国家地理 BBS.NGACN.CC::]

2：闪现宏。
打断当前施法，立即闪现。

#showtooltip 闪现术
/stopcasting
/cast 闪现术

3：法力刚玉宏。
如果当前没有法力刚玉则制造法力刚玉，如果有则使用。

##showtooltip 法力刚玉
/use 法力刚玉
/cast [nocombat] 制造魔法玉石

4：高低级冰箭宏。
直接点用最高级的冰箭，按住ALT在点则是1级冰箭。放风筝的时候比较有用的说。

#showtooltip 寒冰箭
/cast [modifier:alt] 寒冰箭(等级 1); 寒冰箭

变形：

#showtooltip 暴风雪
/cast [modifier:alt] 暴风雪(等级 1); 暴风雪

5：魔爆宏。
不在战斗状态施放1级魔爆，进入战斗则施放最高级。抓潜行不错。

#showtooltip 魔爆术
/cast [nocombat] 魔爆术(等级 1); 魔爆术

6：奥飞宏。
点此宏只会在前一个奥飞施放完之后才能施放下一个，减少不必要的蓝耗。

#showtooltip 奥术飞弹
/cast [nochanneling:奥术飞弹] 奥术飞弹

二：稍微复杂点的宏
1：护甲宏。
直接左键点为熔岩护甲，右键为冰甲，按住ALT再点为法师护甲。

#showtooltip 熔岩护甲
/cast [button:2] 冰甲术; [nomodifier:alt] 熔岩护甲; 法师护甲

2：传送门宏。
直接点传沙塔斯，按住ALT传达纳苏斯，按CTRL传铁炉堡，按SHIFT传暴风城。

/cast [modifier:shift] 传送门：暴风城; [modifier:alt] 传送门：达纳苏斯; [modifier:ctrl] 传送门：铁炉堡; 传送门：沙塔斯

变形：传送。

/cast [modifier:shift] 传送：暴风城; [modifier:alt] 传送：达纳苏斯; [modifier:ctrl] 传送：铁炉堡; 传送：沙塔斯

变形：生活技能。

/cast [modifier:shift] 熔炼; [modifier:alt]急救(大师级) ; [modifier:ctrl]烹饪(大师级) ;珠宝加工(大师级)

3：冰枪自动打图腾。
在不改变当前目标的情况下打最进的根基图腾。

#showtooltip 冰枪术
/stopcasting
/target [exists] 根基图腾
/cast 冰枪术
/targetlasttarget

4：吃喝宏。
左键点喝水、右键啃面包；按住ALT，左键做水、右键做面包。

#showtooltip 魔法冰川水
/use [nomodifier:alt,button:1] 魔法冰川水
/use [nomodifier:alt,button:2] 魔法羊角面包
/cast [modifier:alt,button:1] 造水术
/cast [modifier:alt,button:2] 造食术

5：反制宏。
优先反制鼠标指向的目标；如果鼠标没有指向任何敌对目标，则反制当前目标；按住ALT则反制焦点目标。

#showtooltip 法术反制
/stopcasting
/cast [modifier:alt,target=focus,exists]法术反制;[target=mouseover,exists,harm]法术反制;法术反制

6：解诅咒宏。
优先解除鼠标指向的目标身上的诅咒；如果鼠标没有指向任何目标、或者目标为敌对则解除自己身上的诅咒。

#showtooltip 解除次级诅咒
/cast [target=mouseover, help] 解除次级诅咒; [target=player] 解除次级诅咒;

7：焦点变羊宏。
当你单击这个宏时，如果你没有焦点目标，那么你的当前目标将被设为焦点，并施放变形术。之后单击宏，都会对你的焦点目标重新施放变形术，你可以自由选取目标来输出伤害或者干别的事情。一旦你的焦点目标死亡，再单击这个宏，会设置你的当前目标为焦点，并施放变形术。按ALT再点此宏则把你当前目标改变为焦点目标，并施放变形术。

#showtooltip [target=focus,harm] [] 变形术
/stopcasting
/clearfocus [modifier:alt][target=focus,dead][target=focus,noexists]
/focus [target=focus,noexists]
/cast [target=focus] 变形术

变形：1级羊（PVP时候使用）

#showtooltip [target=focus,harm] [] 变形术(等级 1)
/stopcasting
/clearfocus [modifier:alt][target=focus,dead][target=focus,noexists]
/focus [target=focus,noexists]
/cast [target=focus] 变形术(等级 1)

8：水元素宏。
召唤水元素，如果已有水元素则使用水元素的冰环，如果当前目标是敌对，则命令宠物攻击目标，如果是友善，则命令宠物跟随。如果没有水元素就召唤一个水元素，并设置水元素为被动。

#showtooltip [nopet] [target=pet,dead] 召唤水元素; [pet] 冰冻术
/cast [nopet]召唤水元素
/cast [target=pet,dead]召唤水元素
/stopmacro [target=pet,dead]
/cast 冰冻术
/petpassive
/petattack [harm]
/petfollow [noharm]

9：坐骑宏。
在能使用飞行坐骑的地方随机使用飞行坐骑；在不能使用飞行坐骑的地方随机使用陆地坐骑。如果有诺格弗格药剂效果，会自动取消之后再上马。

#showtooltip [flyable]迅捷紫色狮鹫;[noflyable]黑色军用座虎缰绳
/cancelaura 诺格弗格药剂
/castrandom [nomounted, flyable] 迅捷紫色狮鹫,紫色骑乘虚空鳐
/castrandom [nomounted, noflyable] 迅捷美酒节赛羊,重型紫色雷象,迅捷白色机械陆行鸟,黑色军用座虎缰绳