Question

VMWARE如何删除干净

烦死了，怎么删除都不行！

Answer 1

本文章为大家分享一下怎么删除vmware workstation，下面请看给出的详细讲解。

1、首先在电脑中打开运行，输入appwiz.cpl，如下图所示。

2、然后在打开的窗口中，找到VMware，如下图所示。

3、接着鼠标右键点击，点击更改，如下图所示。

4、最后在打开的页面中，如下图所示，点击删除即可。

Answer 2

把下面的代码粘贴到记事本里，然后点文件-另存为 文件名填"卸载.bat"文件类型选“所有文件”，到了显示“卸载完成……”的时候就OK了
代码：
cls
@echo off
CLS
color 0a
echo 取消DLL文件的注册...
regsvr32 /u /s "%cd%/vmappcfg.dll"
regsvr32 /u /s "%cd%/vmappsdk.dll"
regsvr32 /u /s "%cd%/vmdbCOM.dll"
regsvr32 /u /s "%cd%/vmhwcfg.dll"
regsvr32 /u /s "%cd%\V2V\IntraProcessLogging.dll"
regsvr32 /u /s "%cd%\V2V\reconfig.dll"
regsvr32 /u /s "%cd%\V2V\vhdcvtcom.dll"
regsvr32 /u /s "%cd%\V2V\vmc2vmx.dll"
regsvr32 /u /s "%cd%\V2V\vpcCvt.dll"
echo 正在删除虚拟网卡，请稍后……
:delete VM Network
start /wait vnetlib -- remove adapter vmnet1
start /wait vnetlib -- remove adapter vmnet8
start /wait vnetlib -- remove dhcp vmnet1
start /wait vnetlib -- remove dhcp vmnet8
start /wait vnetlib -- remove nat vmnet8
:delservice
echo 正在删除服务...
call :删除服务 vmnetbridge
call :删除服务 VMAuthdService
call :删除服务 vmx86
call :删除服务 VMnetAdapter
call :删除服务 "VMware NAT Service"
call :删除服务 "VMnetDHCP"
call :删除服务 VMnetuserif
call :删除服务 hcmon
call :删除服务 Vmparport
call :删除服务 vstor2-ws60
call :删除服务 vstor2
call :删除服务 vmkbd
"%cd%\VMMount\vmount2.exe" /Unregserver
netcfg -u vmware_bridge
echo.
:delfile
echo 删除安装的文件....
call :删除文件 %systemroot%\inf\vmnet.sys
call :删除文件 %systemroot%\inf\vmnetBridge.dll
call :删除文件 %systemroot%\inf\netbridge.inf
call :删除文件 %systemroot%\inf\vmnetBridge.sys
call :删除文件 %systemroot%\inf\vmusb.cat
call :删除文件 %systemroot%\inf\vmusb.inf
call :删除文件 %systemroot%\inf\vmusb.sys
call :删除文件 %systemroot%\inf\netadapter.inf
call :删除文件 %systemroot%\inf\vmnetAdapter.sys
call :删除文件 %systemroot%\inf\vnetinst.dll
call :删除文件 %systemroot%\lastgood\system32\drivers\vmnetadapter.sys
call :删除文件 %systemroot%\lastgood\system32\drivers\vmnet.sys
call :删除文件 %systemroot%\lastgood\system32\drivers\vmnetbridge.sys
call :删除文件 %systemroot%\system32\drivers\vmnetadapter.sys
call :删除文件 %systemroot%\system32\drivers\vmnet.sys
call :删除文件 %systemroot%\system32\drivers\vmnetbridge.sys
call :删除文件 %systemroot%\system32\drivers\vmusb.sys
call :删除文件 %systemroot%\system32\drivers\hcmon.sys
call :删除文件 %systemroot%\system32\drivers\vmnetuserif.sys
call :删除文件 %systemroot%\system32\drivers\vmparport.sys
call :删除文件 %systemroot%\system32\drivers\vmx86.sys
call :删除文件 %systemroot%\system32\NETCFG.EXE
call :删除文件 %systemroot%\system32\choice.exe
call :删除文件 %systemroot%\system32\devcon.exe

::以下两句删除用户的配置文件(即虚拟机文件)默认不删除,需要删除请将下面两句前面的::去掉
::rd /s /q %APPDATA%\vmware
::rd /s /q "\Virtual Machines"
echo.
:delreg
echo 删除注册表....
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\VMware, Inc." /f
:deluser
echo 删除用户__vmware_user__...
net user __vmware_user__ /delete
net localgroup __vmware__ /delete

pause>nul|echo 卸载完成......
goto :eof
:删除文件
echo 正在删除文件 %*
del /f /q "%*" >nul 2>nul
goto :eof
:删除服务
echo 正在删除服务 %*
net stop %* 2>nul
sc delete %*
goto :eof

Answer 3

以后删除程序要在控制面板里的--添加与删除程序---卸载自己不需要的程序，卸载的很干净，再把快捷图标删掉就好了