Question

求bat批处理代码：以文本文件中的一列中的学生姓名为文件夹中的照片重命名

老师们好！有个问题麻烦大祌一下，请帮帮忙！谢谢！

我的E盘根目录下有一个文件夹：E:\学籍照片 和一个EXCEL文件：学生基本信息表.xls
现在已经另存为一个 文本文件（制表符分隔） 学生基本信息表.txt
学籍照片 文件夹下存放了一些学生的照片，它是相机按照像的时间顺序自动命名的。
学生基本信息表.xls中录入的是学生的一些信息，它的B列是学生的姓名。（如下面的图片）

现在我想写一个BAT文件，达到以下目的：
用 学生基本信息表中B列的学生姓名 为E:\学籍照片下的照片重新命名。

因为当时给学生照照片的时候是按照学生基本信息表中的学生名单来照的，所以如果把照片按时间顺序排列的话刚好和B列中学生的姓名对应上。

请老师帮帮忙！
谢谢！

Answer 1

放在e:\根目录执行,查看执行结果是否正确，正确后删除第8行的echo后再执行一遍。

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
cd /d "E:\学籍照片"
(for /f "delims=" %%a in ('echo ##^&dir /b/od') do (
    set/p fn=
    if not "%%a"=="##" (  
        for /f "tokens=2 delims=%tab%" %%b in ("!fn!") do (
            echo ren "%%a" "%%b"
        )
    )          
))<"e:\学生基本信息表.txt"
pause

追问

老师，您好！你的答案非常接近成功！只是第一张照片怎么对应的是“民族”，而不是第一个学生的姓名呢？如下面的图，要是去掉“民族”这一行，就完全成功了!请老师再帮帮忙，请帮修改一下，谢谢！

追答

把e:\学生基本信息表.txt文件的前几行贴上来

追问

好的，下面是e:\学生基本信息表.txt文件的前几行的截图：

追答

e:\学生基本信息表.txt文件中的2班以上的内容全删除，即txt文件的第一行为2班    张灿    男........

修改代码：(正确后删除第7行的echo)

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
cd /d "E:\学籍照片"
(for /f "delims=" %%a in ('dir /b/od *.jpg') do (
    set/p fn= 
    for /f "tokens=2 delims=%tab%" %%b in ("!fn!") do (
         echo ren "%%a" "%%b.jpg"
    )          
))<"e:\学生基本信息表.txt"
pause

追问

老师，不删除e:\学生基本信息表.txt文件中的2班以上的内容的话有办法实现吗？我的班级非常多，要是每个班都删除一次的话也是很麻烦的啊！可不可以加上：skip=2 这一句啊？我加了这句再运行，怎么就什么也不显示了呢？

追答

@echo off&setlocal enabledelayedexpansion
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
cd /d "E:\学籍照片"
(for /f "delims=" %%a in ('echo ##^&echo ##^&dir /b/od *.jpg') do (
    set/p fn=
    if not "%%a"=="##" (  
      for /f "tokens=2 delims=%tab%" %%b in ("!fn!") do echo ren "%%a" "%%b.jpg"
    )          
))<"e:\学生基本信息表.txt"
pause

正确后删除第7行echo.

Answer 2

setlocal enabledelayedexpansion
pushd e:\学籍照片
for /f "tokens=*" %%i in (学生基本信息表.txt) do (
set /a n+=1
set #!n!=%%i)
set n=
(for /f "tokens=*" %%i in ('dir/b/od *.jpg') do (
set /a n+=1
call set fn=%%#!n!%%
echo ren "%%i"  "!fn!.jpg"))>dd.bat

运行批处理生成dd.bat在e:\学籍照片，核对无误后运行即可。

追问

sudoku52老师，您好！辛苦您了，您的代码好象不对，它只是在 学籍照片 文件夹下生成了一个dd.bat 文件，我运行它，有两个学生的照片改了名了，一个学生的照片改成了：”（“，连后辍也没有，还有一个改成了”.jpg" 只有后辍，没有学生的姓名。

Answer 3

文本内容格式一致，且照片的文件名按序排列应该可以做到，我应该写不出来，找高手吧！