Question

pascal编程高手快来，骑士游历求助！这里为什么n=5，nsq=25就通不过，n=8，nsq=64就可以

program aaa;
const
n=5;nsq=25;
type
index=1..n;
var
i,j:index;
q:boolean;
a:array[1..2,1..8]of integer;
b:array[1..n,1..n]of integer;
procedure try(x,y:index;i:integer;var q:boolean);
var
k,u,v:integer;
q1:boolean;
begin
k:=0;
repeat
k:=k+1;
q1:=false;
u:=x+a[1,k];
v:=y+a[2,k];
if (u>=1) and (u<=n) and(v>=1) and(v<=8) then
if b[u,v]=0 then
begin
b[u,v]:=i;
if i<nsq then
begin
try(u,v,i+1,q1);
if not q1 then b[u,v]:=0;
end
else q1:=true;
end;
until q1 or(k=8);
q:=q1;
end;
begin

a[1,1]:=-1;a[1,2]:=-2;a[1,3]:=-2;a[1,4]:=-1;a[1,5]:=1;a[1,6]:=2;a[1,7]:=2;a[1,8]:=1;

a[2,1]:=2;a[2,2]:=1;a[2,3]:=-1;a[2,4]:=-2;a[2,5]:=-2;a[2,6]:=-1;a[2,7]:=1;a[2,8]:=2;

for i:=1 to n do

for j:=1 to n do
b[i,j]:=0;
b[1,1]:=1;
try(1,1,2,q);
if q then
for i:=1 to n do
begin
for j:=1 to n do
write(b[i,j]:5);
writeln;
end
else writeln('no solution!');
end.

Answer 1

都是可以的，只是你修改程序时有一处未改好。

program aaa;

const

  n=8; nsq=n*n;        {这里作了小改动}

type

  index=1..n;

var

  i,j:index;

  q:boolean;

  a:array[1..2,1..8]of integer;

  b:array[1..n,1..n]of integer;

procedure try(x,y:index;i:integer;var q:boolean);

  var

     k,u,v:integer;

     q1:boolean;

  begin

    k:=0;

    repeat

       k:=k+1;

       q1:=false;

       u:=x+a[1,k];

       v:=y+a[2,k];

       if (u>=1) and (u<=n) and(v>=1) and(v<=n) then            {这里原来是(v<=8)所以错了}

          if b[u,v]=0 then

            begin

               b[u,v]:=i;

               if i<nsq then

                    begin

                       try(u,v,i+1,q1);

                       if not q1 then b[u,v]:=0;

                    end

                  else q1:=true;

            end;

    until q1 or(k=8);

    q:=q1;

end;

begin

a[1,1]:=-1;a[1,2]:=-2;a[1,3]:=-2;a[1,4]:=-1;a[1,5]:=1;a[1,6]:=2;a[1,7]:=2;a[1,8]:=1;

a[2,1]:=2;a[2,2]:=1;a[2,3]:=-1;a[2,4]:=-2;a[2,5]:=-2;a[2,6]:=-1;a[2,7]:=1;a[2,8]:=2;

   for i:=1 to n do

     for j:=1 to n do

        b[i,j]:=0;

   b[1,1]:=1;

   try(1,1,2,q);

   if q then

      for i:=1 to n do

         begin

           for j:=1 to n do

              write(b[i,j]:5);

           writeln;

         end

      else writeln('no solution!');

end.