Question

vb输入外接圆半径,和中心坐标画出五角星怎么写。

直接在窗体上显示，而且能用滚动条旋转= =

Answer 1

Private Type tPoint
    x As Single
    y As Single
End Type
Private Sub Form_Load()
   HScroll1.Min = 0
   HScroll1.Max = 360
End Sub
Private Sub fun_Paint()
    Const PI As Double = 3.141592653
    Dim intR As Integer
    Dim intO As tPoint
    Dim intK As Integer
    Dim pp(4) As tPoint
    Dim i As Integer
    Me.Cls
    Me.AutoRedraw = True
    intR = Int(Val(Text1.Text))
    intO.x = Int(Val(Text2.Text))
    intO.y = Int(Val(Text3.Text))
    intK = Me.HScroll1.Value
    Me.DrawWidth = 10
    Me.PSet (intO.x, intO.y), vbRed
    For i = 0 To 4
        pp(i).x = intO.x + intR * Sin(((intK + 72 * i) / 360) * (2 * PI))
        pp(i).y = intO.y + intR * Cos(((intK + 72 * i) / 360) * (2 * PI))
        Me.DrawWidth = 6
        Me.PSet (pp(i).x, pp(i).y), vbBlue
    Next i
    Me.DrawWidth = 3
    For i = 0 To 4
        Me.Line (pp(i).x, pp(i).y)-(pp((i + 2) Mod 5).x, pp((i + 2) Mod 5).y), vbBlack
    Next
End Sub

Private Sub Form_Click()
    fun_Paint
End Sub

Private Sub HScroll1_Change()
    fun_Paint
End Sub

Private Sub HScroll1_Scroll()
    fun_Paint
End Sub

Answer 2

楼主看看这个：

' 窗体内画一个水平滚动条 HScroll1 、一个按钮 Command1
Private Const PI As Double = 3.14159265359    '圆周率 π
Private mlR As Long

Private Sub DrawPentacle()
   Dim w As Long, h As Long
   Dim i As Long, a As Double
   Dim v As Long, p As Long
   Dim xa#, xb#, ya#, yb#
   
   v = HScroll1.Value
   w = ScaleWidth / 2
   h = ScaleHeight / 2
   Me.Cls: p = 0
   a = v * PI / 180
   xa = w + mlR * Sin(a)
   ya = h - mlR * Cos(a)
   For i = 1 To 5
      p = (p + 2) Mod 5
      a = ((v + 72 * p) * PI / 180)
      xb = w + mlR * Sin(a)
      yb = h - mlR * Cos(a)
      Line (xa, ya)-(xb, yb), vbRed
      xa = xb: ya = yb
   Next
End Sub

Private Sub Command1_Click()
   Dim v As Long
   v = Val(InputBox("请输入半径（以象素为单位）：", "输入", "150"))
   If (v < 1 Or v > 800) Then
      MsgBox "输入不正确。", 32
      Exit Sub
   End If
   mlR = v
   Call DrawPentacle
End Sub

Private Sub Form_Load()
   ScaleMode = 3
   HScroll1.TabStop = False
   HScroll1.Min = 0
   HScroll1.Max = 360
End Sub

Private Sub HScroll1_Change()
   Call DrawPentacle
End Sub

Private Sub HScroll1_Scroll()
   Call DrawPentacle
End Sub

追问

我的程序是这样的怎么改啊

追答

你新建一个工程，按我的代码、说明做呗。
看你的代码，能画出五角星吗……

你要让别人给你改代码，直接贴代码啊或发工程啊，
你贴图片，别人要把你的代码“敲一遍”，你不认为很劲吗！！！

追问

好吧，我把程序给你看看，因为没办法，老师要答辩的，什么都不懂不大好。http://kuai.xunlei.com/d/iMb9BcLGFkGtUgQA251

追答

你这个代码，跟你提问时说的完全是两回事啊！

你不是说要用滚动条来“旋转”吗？
你的代码根本就不能正确画图。
是你老师要求你要画“实心五角星”的吗？
如果要画实心的，因为这里面涉及填充“倾斜的三角形”。
这种情况，要么用GDI+的API函数来画，
要么就是要用很复杂的“算法”在VB中用画线的方式来填充。
你确定要画实心的？？？？

追问

我指的实心的五角星就是那种内接五边形的那种，我现在能实现的就是输入中心坐标，外接圆半径按两个按键出现两种五角星，因为老师要求200行代码，我还差了不少，所以我想加点其他的功能，我就想画出来的这两种五角星能不能用滚动条进行旋转。我还想过变颜色，但好像试过好几种方法都不成功

追答

没懂你说的“内接五边形那种”是什么样的。

你手工画一个图片发出来看看。
当然不要求你把图片画得很规矩，关键是要让别人能明白是怎么回事。
你画一个空心的五角星是什么样子、半径r的圆轮廓在哪，
　　实心的五角星是什么样子、半径r的圆轮廓在哪。
把图片贴出来。
晕，又是一个”要求要有200行代码“的老师……
你得问问你的老师，变量声明行、注释行、 Funtion/Sub XXXX 和 End Funtion/Sub、
　　和过程之间的一个空行，这些算不算在”行数“之内？？？
-_-!!!

追问

已经私信你了