Question

如何判断RadioButton被选中（NSIS）

在NSIS中，如果判断RadioButton被选中。如果被选中，弹出Messagebox“被选中”；如果没有选中，弹出Messagebox“没有选中”。

Answer 1

#使用 ${NSD_GetState} 和 ${NSD_SetState} 来获取和设置其状态
!include nsDialogs.nsh
!include LogicLib.nsh

Name nsDialogs
OutFile nsDialogs.exe

XPStyle on

Var Dialog
Var Label
Var Text
Var Text_State
Var Checkbox
Var Checkbox_State

Page custom nsDialogsPage nsDialogsPageLeave
Page license
Page instfiles

Function .onInit

	StrCpy $Text_State "Type something here..."

FunctionEnd

Function nsDialogsPage

	nsDialogs::Create /NOUNLOAD 1018
	Pop $Dialog

	${If} $Dialog == error
		Abort
	${EndIf}

	${NSD_CreateLabel} 0 0 100% 12u "Hello, welcome to nsDialogs!"
	Pop $Label

	${NSD_CreateText} 0 13u 100% 12u $Text_State
	Pop $Text

	${NSD_CreateCheckbox} 0 30u 100% 10u "&Something"
	Pop $Checkbox

	${If} $Checkbox_State == ${BST_CHECKED}
		${NSD_Check} $Checkbox
	${EndIf}
	
	# alternative for the above ${If}:
	#${NSD_SetState} $Checkbox_State

	nsDialogs::Show

FunctionEnd

Function nsDialogsPageLeave

	${NSD_GetText} $Text $Text_State
	${NSD_GetState} $Checkbox $Checkbox_State

FunctionEnd

Section

	DetailPrint "hello world"

SectionEnd

以上是官方教程，略做改动就能应用到RadioButton里了。

eg:

Var RadioButton1

${NSD_CreateRadioButton} 44 291 50 20 "Others"

Pop $RadioButton1

${NSD_GetState} $RadioButton1 $1

${If} $1==${BST_CHECKED}

    MessageBox MB_OK "RadioButton1 被选中啦！" 

${EndIf}

Answer 2

要看你是在哪使用的这个 RadioButton 了，自定义页面的话，也分 MUI 和 MUI2。

Answer 3

Boolean a=this.RadioButton名字.checked;if(a){Messagebox.show("被选中");}else{Messagebox.show("没有选中");}