Question

易语言中的“如果”“如果真”和“判断”的区别是什么？

我的脑子好乱啊~~~~~~！！

Answer 1

【如果真】通常用在处理一各简单判断行为，只能执行条件为真的命令。
【判断】多用于大于两个条件的判断。当条件为真是不在判断下去。否则就继续沿着左侧箭头向下执行。
【如果】在【如果真】的基础上增加了条件为假时的反应。【判断】也是如此。当条件为真是不在判断下去。否则就继续沿着左侧箭头向下执行，在这点上【如果】和【判断】是相同的。

Answer 2

版本 2

.程序集 窗口程序集1, , , 在启动窗口添加三个按钮，分别命名为：如果真_按钮、如果_按钮、判断_按钮，在窗口空白处双击，将这里的全部代码粘贴到窗口程序集1，运行程序测试

.子程序 如果真_举例, , , 只需要对单个条件进行处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.如果真 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.如果真结束

.子程序 如果_举例, , , 需要对条件成立、不成立分别处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.如果 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.否则
' 输入内容不是数字1时窗口移到屏幕最右边
_启动窗口.左边 ＝ 取屏幕宽度 () － _启动窗口.宽度

.如果结束

.子程序 判断_举例, , , 需要对多个条件进行处理
.局部变量 输入内容, 文本型

输入框 (“请输入一个数字！”, , “1”, 输入内容, #输入整数)
.判断开始 (输入内容 ＝ “1”)
' 输入内容是数字1时窗口移到屏幕最左边
_启动窗口.左边 ＝ 0
.判断 (输入内容 ＝ “2”)
' 输入内容是数字2时窗口移到屏幕最右边
_启动窗口.左边 ＝ 取屏幕宽度 () － _启动窗口.宽度
.判断 (输入内容 ＝ “3”)
' 输入内容是数字3时窗口移到屏幕中间、上方,
_启动窗口.左边 ＝ (取屏幕宽度 () － _启动窗口.宽度) ÷ 2
_启动窗口.顶边 ＝ 0
.判断 (输入内容 ＝ “4”)
' 输入内容是数字3时窗口移到屏幕中间、下方,
_启动窗口.左边 ＝ (取屏幕宽度 () － _启动窗口.宽度) ÷ 2
_启动窗口.顶边 ＝ 取屏幕高度 () － _启动窗口.高度
.默认

.判断结束

.子程序 _如果真_按钮_被单击

如果真_举例 ()

.子程序 _如果_按钮_被单击

如果_举例 ()

.子程序 _判断_按钮_被单击

判断_举例 ()这也是我从网上找的资料 看来我还得多了解易语言了

Answer 3

如果真 相当于 如果 没有否则那部分而 判断 是满足对多个条件的支持