Question

求cmd高手！！我想用bat文件清楚u盘的里文件的系统属性，要带提示性操作的（Y/N）

bat文件打开后，要求效果：
1、提示是否清理系统属性？（Y/N）；
2、 然后提示输入u盘盘符；
3、 然后就开始了。
请问用cmd可以做吗，用别的语言也行，最好不用特意安装编程软件就能做好的
清理代码用attrib -s -h -r x:\*.* /s /d 可以吗

Answer 1

你是要把U盘里所有文件、文件夹、子文件夹都去掉全部属性呀。用你的命令应该可以。

或者：for /r %%i in (*.*) do attrib %%i -s -h -r -a >nul 2>nul

第一项你只要在批处理中加个判断语句，第二项只要设置一个变量就OK了。

全文可以如下：

cls
:rf
echo.
SET Choice=
SET /P Choice= 是否清理系统属性（Y/N），然后按回车：
IF NOT '%Choice%'=='' SET Choice=%Choice:~0,1%
echo.
IF /I '%Choice%'=='y' GOTO one
IF /I '%Choice%'=='n' GOTO end
echo "%Choice%" 选择无效，请重新输入：
echo.
GOTO rf
:one
SET /P label= 键入U盘的盘符(例如：i)，然后按回车：
cd /d %label%:\
for /r %%i in (*.*) do attrib %%i -s -h -r -a >nul 2>nul
:end
exit

Answer 2

@Echo Off
Set /p yn=请选择是否清理系统属性？（Y/N）:
If /i not %yn%==y (Exit)
Set /p Label=请输入u盘盘符(例如 x:):
Attrib -s -h -r %Label%\*.* /s /d
Pause

追问

你好，你写的实现了我想要的功能，只是发现有个地方不是太完善，比如要是输入的盘符格式不对，例如少输入了冒号，能让它自己返回到提示重新输入吗，现在的话，输入错误也就执行结束了，谢谢

追答

@Echo Off
Set /p yn=请选择是否清理系统属性？（Y/N）:
If /i not %yn%==y (Exit)
Set /p Label=请输入u盘盘符(例如 x:):
Echo %Label%|Find ":"||Set Label=%Label%:
Attrib -s -h -r %Label%\*.* /s /d
Pause

本来想写判断提示的,但后来觉得直接修改变量就好了,现在有没有输入冒号都可以正常运行.