Question

易语言问题，如何取所有编辑框里的数字最小的是多少？

比如有50个编辑框，怎么快速知道所有编辑框最小的金额是多少？还有第三小金额多少？又如何统计出50个编辑框里大于0的有几个？谢谢大师指点

Answer 1

.版本 2

.程序集 窗口程序集1

.子程序 __启动窗口_创建完毕

.局部变量 x, 整数型

.局部变量 y, 整数型

.局部变量 z, 整数型

.局部变量 编辑框变量, 编辑框

置随机数种子 ()

.计次循环首 (50, x)

    复制窗口组件 (编辑框, 编辑框变量)

    编辑框变量.移动 (((x － 1) ％ 10) × 编辑框.宽度 ＋ 编辑框.左边, ((x － 1) ＼ 10) × 编辑框.高度 ＋ 编辑框.顶边, , )

    编辑框变量.可视 ＝ 真

    y ＝ 取随机数 (0, 20)

    z ＝ 取随机数 (0, 10)

    y ＝ y － z

    编辑框变量.内容 ＝ 到文本 (y)

    编辑框变量.标记 ＝ 到文本 (x)

.计次循环尾 ()

.子程序 _按钮1_被单击

.局部变量 x, 整数型

.局部变量 y, 整数型

.局部变量 编辑框变量, 编辑框

编辑框变量 ＝ 取标记组件 (1)

y ＝ 到整数 (编辑框变量.内容)

.计次循环首 (50, x)

    编辑框变量 ＝ 取标记组件 (x)

    .如果真 (到整数 (编辑框变量.内容) ＜ y)

        y ＝ 到整数 (编辑框变量.内容)

    .如果真结束

.计次循环尾 ()

编辑框1.内容 ＝ 到文本 (y)

.子程序 _按钮2_被单击

.局部变量 数组1, 整数型, , "0"

.局部变量 临时文本, 文本型

.局部变量 x, 整数型

.局部变量 编辑框变量, 编辑框

.计次循环首 (50, x)

    编辑框变量 ＝ 取标记组件 (x)

    .如果真 (寻找文本 (临时文本, “[” ＋ 编辑框变量.内容 ＋ “]”, 0, 假) ＜ 0)

        临时文本 ＝ 临时文本 ＋ “[” ＋ 编辑框变量.内容 ＋ “]”

        加入成员 (数组1, 到整数 (编辑框变量.内容))

    .如果真结束

.计次循环尾 ()

数组排序 (数组1, 真)

编辑框2.内容 ＝ 到文本 (数组1 [3])

.子程序 _按钮3_被单击

.局部变量 x, 整数型

.局部变量 y, 整数型

.局部变量 编辑框变量, 编辑框

y ＝ 0

.计次循环首 (50, x)

    编辑框变量 ＝ 取标记组件 (x)

    .如果真 (到整数 (编辑框变量.内容) ＞ 0)

        y ＝ y ＋ 1

    .如果真结束

.计次循环尾 ()

编辑框3.内容 ＝ 到文本 (y)

Answer 2

告诉你方法，具体代码最好自己写：首先对每个编辑框设置标记（编辑框的属性那里填上），最好按顺序标记1-50，如编辑框1的标记为1，编辑框的标记为2......，然后用命令取标记组件（）命令就可以循环得到每个编辑框里面的内容，加入到数组中，然后排序即可（要记得对应的下标）。如果不知道怎么记住对应下标的话就用多一个数组，一个数组放下标，一个数组放内容，排序的时候两个数组同步变化即可。