Question

怎么修改网吧的桌面背景

我是一个网吧的网管,我想给网吧做一个个性化的桌面背景,可是我从超管模式进去以后改完重起还是没有用,我们这超管的模式也没有控制C盘的权限.
我想问下,我怎么才能更改?急
哪位好心的高手快告诉我吧

Answer 1

@echo off

rem 设置服务器图片路径[BMP图片的文件夹]，只支持BMP格式[如果数量超过1000张，多出的图片将不被本脚本读取]
set 图片路径=D:\游戏菜单\客户端\Logon\

rem 设置网络不通时，本地图片的路径[单个BMP图片的完整路径]
set 本地图片=D:\游戏菜单\客户端\Logon\桌面.bmp

dir/b/s "%图片路径%\*.bmp" |find /i /n ".bmp" >"bmp.txt"
for %%i in (bmp.txt) do if %%~zi EQU 0 goto 更换
for /f "delims=[]" %%i in (bmp.txt) do @set Num1=%%i
if %Num1% LSS 10 (Set Num3=1) Else (if %Num1% LSS 100 (Set Num3=2) Else Set Num3=3)
:GetRandom
call set Num2=%%random:~-%Num3%%%
if %Num2% GTR %Num1% goto GetRandom
for /f "tokens=* delims=0" %%i in ("%Num2%") do set Num2=%%i
if "%Num2%" EQU "" set Num2=%Num1%
set bmppath=
for /f "tokens=1* delims=[]" %%i in (bmp.txt) do @if /i %%i==%Num2% set bmppath=%%j
del bmp.txt
:更换
if not exist "%图片路径%" set bmppath=%本地图片%
if not exist "%bmppath%" set bmppath=%本地图片%
@reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v TileWallpaper /d "0" /f>nul
@reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v Wallpaper /d "%bmppath%" /f>nul
@reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v WallpaperStyle /d "2" /f>nul
@reg add "HKEY_CURRENT_USER\Control Panel\Desktop" /v Wallpaper /d "%bmppath%" /f>nul
@reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ListviewShadow /d "1" /f>nul
RunDll32.exe USER32.DLL,UpdatePerUserSystemParameters
set bmppath=
rem gpupdate /force
@exit

Answer 2

你如果是无盘,只要在服务器上修改就可以了,如果是C/S,那就简单了,去掉所有硬盘保护,打开你要做背景的图片,然后右击发送到桌面背景就行了

Answer 3

估计电脑上都装的还原卡，所以你作的都不能保存。