Question

如何在vb中打开Excel

我要设计一个关于做帐的软件,在vb中，输入数目，单价，型号，设3个命令按纽，一个是知道计算总价格，一个是打开Excel，还有就是自动把数据填入Excel表格中（注意：第二次输入仍能在那张表格中继续往下自动填入）会的请写出教程，也可以编好了发到我邮箱里：7351742432qq.com(好的话追100分）

Answer 1

Visual Basic开发工具模式可以直接从Excel表格中进入，不需要另外打开。

具体步骤：

1、在电脑上桌面上找到Excel表格图标，双击打开。

2、打开Excel软件后，点击左上角按钮。

3、点击后会弹出一个菜单，在菜单中点击Excel选项按钮。

4、然后在弹出的对话框中勾选自定义功能区中的“开发工具”。

5、然后点击右下方确定按钮。

6、点击确定后，会返回Excel页面。

7、然后在Excel上方的导航栏中点击开发工具按钮。

8、然后在开发工具页面，点击Visual Basic选项。

9、点击后就会进入Visual Basic开发模式。

10、点击左侧导航栏中的Excel中的sheet表格，就可以在Visual Basic中打开了。

Answer 2

这份教程我曾给过很多人了,大家都说好,您也看一下吧

VB是常用的应用软件开发工具之一，由于VB的报表功能有限，而且一但报表格式发生变化，就得相应修改程序，给应用软件的维护工作带来极大的不便。因此有很多程序员现在已经充分利用EXECL的强大报表功来实现报表功能。但由于VB与EXCEL由于分别属于不同的应用系统，如何把它们有机地结合在一起，是一个值得我们研究的课题。

一、 VB读写EXCEL表：

VB本身提自动化功能可以读写EXCEL表，其方法如下：

1、在工程中引用Microsoft Excel类型库：

从"工程"菜单中选择"引用"栏；选择Microsoft Excel 9.0 Object Library（EXCEL2000），然后选择"确定"。表示在工程中要引用EXCEL类型库。

2、在通用对象的声明过程中定义EXCEL对象：

Dim xlApp As Excel.Application
Dim xlBook As Excel.WorkBook
Dim xlSheet As Excel.Worksheet

3、在程序中操作EXCEL表常用命令：

Set xlApp = CreateObject("Excel.Application") '创建EXCEL对象
Set xlBook = xlApp.Workbooks.Open("文件名") '打开已经存在的EXCEL工件簿文件
xlApp.Visible = True '设置EXCEL对象可见（或不可见）
Set xlSheet = xlBook.Worksheets("表名") '设置活动工作表
xlSheet.Cells(row, col) =值 '给单元格（row,col）赋值
xlSheet.PrintOut '打印工作表
xlBook.Close (True) '关闭工作簿
xlApp.Quit '结束EXCEL对象
Set xlApp = Nothing '释放xlApp对象
xlBook.RunAutoMacros (xlAutoOpen) '运行EXCEL启动宏
xlBook.RunAutoMacros (xlAutoClose) '运行EXCEL关闭宏

4、在运用以上VB命令操作EXCEL表时，除非设置EXCEL对象不可见，否则VB程序可继续执行其它操作，也能够关闭EXCEL，同时也可对EXCEL进行操作。但在EXCEL操作过程中关闭EXCEL对象时，VB程序无法知道，如果此时使用EXCEL对象，则VB程序会产生自动化错误。形成VB程序无法完全控制EXCEL的状况，使得VB与EXCEL脱节。

二、 EXCEL的宏功能：

EXCEL提供一个Visual Basic编辑器，打开Visual Basic编辑器，其中有一工程属性窗口，点击右键菜单的"插入模块"，则增加一个"模块1"，在此模块中可以运用Visual Basic语言编写函数和过程并称之为宏。其中，EXCEL有两个自动宏：一个是启动宏（Sub Auto_Open()），另一个是关闭宏（Sub Auto_Close()）。它们的特性是：当用EXCEL打含有启动宏的工簿时，就会自动运行启动宏，同理，当关闭含有关闭宏的工作簿时就会自动运行关闭宏。但是通过VB的自动化功能来调用EXCEL工作表时，启动宏和关闭宏不会自动运行，而需要在VB中通过命令xlBook.RunAutoMacros (xlAutoOpen)和xlBook.RunAutoMacros (xlAutoClose) 来运行启动宏和关闭宏。

三、 VB与EXCEL的相互勾通：

充分利用EXCEL的启动宏和关闭宏，可以实现VB与EXCEL的相互勾通，其方法如下：

在EXCEL的启动宏中加入一段程序，其功能是在磁盘中写入一个标志文件，同时在关闭宏中加入一段删除此标志文件的程序。VB程序在执行时通过判断此标志文件存在与否来判断EXCEL是否打开，如果此标志文件存在，表明EXCEL对象正在运行，应该禁止其它程序的运行。如果此标志文件不存在，表明EXCEL对象已被用户关闭，此时如果要使用EXCEL对象运行，必须重新创建EXCEL对象。

四、举例：

1、在VB中，建立一个FORM，在其上放置两个命令按钮，将Command1的Caption属性改为EXCEL，Command2的Caption属性改为End。然后在其中输入如下程序：

Dim xlApp As Excel.Application '定义EXCEL类
Dim xlBook As Excel.Workbook '定义工件簿类
Dim xlsheet As Excel.Worksheet '定义工作表类
Private Sub Command1_Click() '打开EXCEL过程
If Dir("D:\temp\excel.bz") = "" Then '判断EXCEL是否打开
Set xlApp = CreateObject("Excel.Application") '创建EXCEL应用类
xlApp.Visible = True '设置EXCEL可见
Set xlBook = xlApp.Workbooks.Open("D:\temp\bb.xls") '打开EXCEL工作簿
Set xlsheet = xlBook.Worksheets(1) '打开EXCEL工作表
xlsheet.Activate '激活工作表
xlsheet.Cells(1, 1) = "abc" '给单元格1行驶列赋值
xlBook.RunAutoMacros (xlAutoOpen) 运行EXCEL中的启动宏
Else
MsgBox ("EXCEL已打开")
End If
End Sub

Private Sub Command2_Click()
If Dir("D:\temp\excel.bz") <> "" Then '由VB关闭EXCEL
xlBook.RunAutoMacros (xlAutoClose) '执行EXCEL关闭宏
xlBook.Close (True) '关闭EXCEL工作簿
xlApp.Quit '关闭EXCEL
End If
Set xlApp = Nothing '释放EXCEL对象
End
End Sub

2、在D盘根目录上建立一个名为Temp的子目录，在Temp目录下建立一个名为"bb.xls"的EXCEL文件。

3、在"bb.xls"中打开Visual Basic编辑器，在工程窗口中点鼠标键选择插入模块，在模块中输入入下程序存盘：

Sub auto_open()
Open "d:\temp\excel.bz" For Output As #1 '写标志文件
Close #1
End Sub
Sub auto_close()
Kill "d:\temp\excel.bz" '删除标志文件
End Sub

4、运行VB程序，点击EXCEL按钮可以打开EXCEL系统，打开EXCEL系统后，VB程序和EXCEL分别属两个不同的应用系统，均可同时进行操作，由于系统加了判断，因此在VB程序中重复点击EXCEL按钮时会提示EXCEL已打开。如果在EXCEL中关闭EXCEL后再点EXCEL按钮，则会重新打开EXCEL。而无论EXCEL打开与否，通过VB程序均可关闭EXCEL。这样就实现了VB与EXCEL的无缝连接。

Answer 3

单击“工程”菜单，引用，找到“Microsoft Excel xx Object Library”并勾选他，确定。我直接给你一个Frm文件吧，否则好多东西不方便说。也就是把下面的代码保存成一个.Frm文件。
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
VERSION 5.00
Begin VB.Form Form1
Caption = "Form1"
ClientHeight = 3195
ClientLeft = 60
ClientTop = 345
ClientWidth = 4680
LinkTopic = "Form1"
ScaleHeight = 3195
ScaleWidth = 4680
StartUpPosition = 3 '窗口缺省
Begin VB.CommandButton Command3
Caption = "填入"
Height = 375
Left = 2280
TabIndex = 10
Top = 2400
Width = 855
End
Begin VB.CommandButton Command2
Caption = "打开"
Height = 375
Left = 1200
TabIndex = 9
Top = 2400
Width = 855
End
Begin VB.CommandButton Command1
Caption = "计算"
Height = 375
Left = 120
TabIndex = 8
Top = 2400
Width = 855
End
Begin VB.TextBox Text2
Height = 375
Left = 1680
TabIndex = 7
Top = 720
Width = 1575
End
Begin VB.TextBox Text1
Height = 375
Left = 0
TabIndex = 6
Top = 720
Width = 1455
End
Begin VB.TextBox Text4
Height = 375
Left = 1680
TabIndex = 5
Top = 1800
Width = 1335
End
Begin VB.TextBox Text3
Height = 375
Left = 120
TabIndex = 4
Top = 1800
Width = 1335
End
Begin VB.Label Label4
Caption = "总价"
Height = 255
Left = 1560
TabIndex = 3
Top = 1440
Width = 975
End
Begin VB.Label Label3
Caption = "类型"
Height = 255
Left = 0
TabIndex = 2
Top = 1440
Width = 1215
End
Begin VB.Label Label2
Caption = "单价"
Height = 255
Left = 1680
TabIndex = 1
Top = 360
Width = 735
End
Begin VB.Label Label1
Caption = "数量"
Height = 255
Left = 0
TabIndex = 0
Top = 360
Width = 375
End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Dim xls As Excel.Application, wbk As Excel.Workbook, sht As Object, i As Integer

Private Sub Command1_Click()
Text4.Text = Text1.Text * Text2.Text
End Sub

Private Sub Command2_Click()
Set xls = New Excel.Application
xls.Visible = True
Set wbk = xls.Workbooks.Add
Set sht = wbk.Sheets("sheet1")
sht.Cells(1, 1).Value = "数量"
sht.Cells(1, 2).Value = "单价"
sht.Cells(1, 3).Value = "类型"
sht.Cells(1, 4).Value = "总价"
i = 1
End Sub

Private Sub Command3_Click()
i = i + 1
sht.Cells(i, 1).Value = Text1.Text
sht.Cells(i, 2).Value = Text2.Text
sht.Cells(i, 3).Value = Text3.Text
sht.Cells(i, 4).Value = Text4.Text
Text1.Text = ""
Text2.Text = ""
Text3.Text = ""
Text4.Text = ""
End Sub

Answer 4

引用皮蛋粯子粥的回答：
Visual Basic开发工具模式可以直接从Excel表格中进入，不需要另外打开。
具体步骤：
1、在电脑上桌面上找到Excel表格图标，双击打开。

2、打开Excel软件后，点击左上角按钮。

3、点击后会弹出一个菜单，在菜单中点击Excel选项按钮。

4、然后在弹出的对话框中勾选自定义功能区中的“开发工具”。

5、然后点击右下方确定按钮。

6、点击确定后，会返回Excel页面。

7、然后在Excel上方的导航栏中点击开发工具按钮。

8、然后在开发工具页面，点击Visual Basic选项。

9、点击后就会进入Visual Basic开发模式。

10、点击左侧导航栏中的Excel中的sheet表格，就可以在Visual Basic中打开了。

VB不是VBA