Question

【求助】怎样用批处理把文件夹修改目录下icon.ico图标?

需要两个批处理
1.一个是更改bat所在目录icon.ico的文件夹图标
2.一个是修改bat所在目录,所有子文件夹的所有图标

支持文件夹是中文,比如
【这是-一个文件夹[测试]】

Answer 1

@echo off
set #=q&set/azx=0x53b7e0b4
title Any question +%#%%#% %zx%
cd /d "%~dp0"
set "ico文件=D:\icon.ico"
if not exist "%ico文件%" (echo;"%ico文件%" not found&goto end)
:main
cls
echo;1 更改bat所在目录的文件夹图标
echo;2 更改bat所在目录下所有子文件夹的文件夹图标
echo;
set "c="
set /p c=输入数字序号并按回车键:
if "%c%" equ "1" goto :a
if "%c%" equ "2" goto :b
goto main
:a
del /a /f /q desktop.ini 2>nul
(echo;[.ShellClassInfo]
echo;IconResource=%ico文件%)>desktop.ini
attrib +s +h desktop.ini
attrib +s "%cd%"
goto end
:b
for /f "delims=" %%a in ('dir /ad/b/s') do (
del /a /f /q "%%a\desktop.ini" 2>nul
(echo;[.ShellClassInfo]
echo;IconResource=%ico文件%)>"%%a\desktop.ini"
attrib +s +h "%%a\desktop.ini"
attrib +s "%%a"
)
:end
echo;如果图标没有立即生效，刷新几下
echo;Any question +%#%%#% %zx%
pause

追问

太感谢了,测试了下功能实现了,但进一步测试发现修改成功后,如果把修改后的文件夹移动其他路径,更改图标就失效了,请问如何才能让文件夹图标更改后一直存在,即使更换路径也不变呢,希望更改图标打包压缩包,分享给别人,别人解压后也能看到本地修改后效果

追答

ico文件的路径保持跟原来一致就行了

追问

_(:з」∠)_谢了,我参考你的代码,自己修改了下,已经完美实现移动其他路径也不会还原更改后的图标功能