Question

请教asp如何实现水印效果

我已经看了很多!但是都不好似很详细！
我想知道具体怎么应用！
麻烦大家了！！

Answer 1

以ASPJPEG为例(服务器必须已安装该组件)
如你测试使用没有的话,将MAIL地址消息给我,发送组件给你.

下面是我自己使用的水印处理过程.如需要ASP文请消息中注明:

'生成水印文字:aspjpeg_water(12)
'参数说明:
'aspjpeg_water_fro-来源路径
'aspjpeg_water_tar-保存路径
'aspjpeg_water_txt-水印文本
'aspjpeg_water_fac-水印字体
'aspjpeg_water_siz-水印字号
'aspjpeg_water_bod-是否黑体
'aspjpeg_water_ita-是否斜体
'aspjpeg_water_und-是否下划线
'aspjpeg_water_qua-清晰度
'aspjpeg_water_mod-透明模式
'aspjpeg_water_xwz-水印X坐标
'aspjpeg_water_ywz-水印Y坐标
Sub aspjpeg_water(aspjpeg_water_fro,aspjpeg_water_tar,aspjpeg_water_txt,aspjpeg_water_fac,aspjpeg_water_siz,aspjpeg_water_bod,aspjpeg_water_ita,aspjpeg_water_und,aspjpeg_water_qua,aspjpeg_water_mod,aspjpeg_water_xwz,aspjpeg_water_ywz)
Set lq_aspjpeg = Server.CreateObject("Persits.Jpeg")
lq_aspjpeg.Open Server.MapPath(""&aspjpeg_water_fro&"")
'水印背景颜色
lq_aspjpeg.Canvas.Font.BkColor=&H0000FF
'水印前景颜色
lq_aspjpeg.Canvas.Font.Color=&HFFFFFF
'水印文本字体
lq_aspjpeg.Canvas.Font.Family=aspjpeg_water_fac
'水印文本大小
lq_aspjpeg.Canvas.Font.size=aspjpeg_water_siz
'水印文本黑体
if aspjpeg_water_bod=0 then
lq_aspjpeg.Canvas.Font.Bold=False
else
lq_aspjpeg.Canvas.Font.Bold=True
end if
'水印文本斜体
if aspjpeg_water_ita=0 then
lq_aspjpeg.Canvas.Font.Italic=False
else
lq_aspjpeg.Canvas.Font.Italic=True
end if
'水印文本下划线
if aspjpeg_water_und=0 then
lq_aspjpeg.Canvas.Font.Underlined=False
else
lq_aspjpeg.Canvas.Font.Underlined=True
end if
'水印文字清晰度
lq_aspjpeg.Canvas.Font.Quality=aspjpeg_water_qua
'透明模式Opaque(不透明使用背景色)/Transparent(透明)
if aspjpeg_water_mod=0 then
lq_aspjpeg.Canvas.Font.BkMode="Opaque"
else
lq_aspjpeg.Canvas.Font.BkMode="Transparent"
end if
'水印倾斜角度
lq_aspjpeg.Canvas.Font.Rotation=0
'水印文字及位置
if aspjpeg_water_ywz=0 then
lq_aspjpeg.Canvas.Print aspjpeg_water_xwz,lq_aspjpeg.Height-20,aspjpeg_water_txt
else
lq_aspjpeg.Canvas.Print aspjpeg_water_xwz,aspjpeg_water_ywz,aspjpeg_water_txt
end if
lq_aspjpeg.Save Server.MapPath(""&aspjpeg_water_tar&"")
lq_aspjpeg.Close
Set lq_aspjpeg=Nothing
End Sub

'演示的例子(将图片来源和目标地址设置为1个则自动在原图上加水印文字):
SaveFile="./upfile/aaa.jpg"
file_copy=" Upload By Administrator"
aspjpeg_water SaveFile,SaveFile,file_copy,"verdana",17,0,0,0,0,0,2,0

Answer 2

有水印组件的，常用的aspJPEG可以实现。但是服务器上必须要安装该组件才可以。

有个参考教程：http://www.knowsky.com/4320.html