Question

vbs添加计划任务

VBS给xp系统添加计划任务 懂得高手赐教下 感谢。

Answer 1

'Win32_ScheduledJob Create 方法的格式：
'uint32 Create(
' [in] string Command, '计划服务要执行的命令、批处理或可执行程序(与命令行参数一起)
' [in] datetime StartTime, '计划任务执行的时间，比如在23:01:05执行上面的命令、批处理或可执行程序
' [in, optional] boolean RunRepeatedly, '是否反复执行，当为 False时，只执行一次
' [in, optional] uint32 DaysOfWeek, '此参数是指每星期几执行计划任务，下面的例子里是一星期每天都执行
' [in, optional] uint32 DaysOfMonth, '这个参数是指一个月里的那天执行计划任务，下面的例子里省略了
' [in, optional] boolean InteractWithDesktop, '这个参数是指计划任务是否可以与前台用户交互，下面的例子省略了
' [out] uint32 JobId '这个参数用于获取到创建计划任务完成后的ID
');
'该方法返回一个整数，其意义分别如下：
'0 - 成功完成，
'1 - 不支持，
'2 - 访问被拒绝，
'8 - 出现不明故障，
'9 - 未发现路径，
'21 - 参数无效，
'22 - 服务尚未启动，

'JobId可以在完成后直接读取，这是计划任务的ID，用于指定删除那个任务
'例：
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set objNewJob = objWMIService.Get("Win32_ScheduledJob")
errJobCreated = objNewJob.Create( _
"J:\bat\修改IP_2.bat", _
"********230105.000000+480", _
True , _
1 OR 2 OR 4 OR 8 OR 16 Or 32 OR 64 , _
, _
, _
JobID)
Select Case errJobCreated
Case 0 State = "成功完成"
Case 1 State = "不支持"
Case 2 State = "访问被拒绝"
Case 8 State = "出现不明故障"
Case 9 State = "未发现路径"
Case 21 State = "参数无效"
Case 22 State = "服务尚未启动"
Case Else State = "状态未知"
End Select
Wscript.Echo "创建计划任务：" & State & vbcrlf & "计划任务的ID：" & JobId

Answer 2

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set objNewJob = objWMIService.Get("Win32_ScheduledJob")errJobCreated = objNewJob.Create（……）系统计划任务在于计算机的资源管理器在运行时按脚本要求定时多次执行任务，而你提出的要求是启动项的功能，完全可以放入注册表RUN中。