Question

求大神解决CAD LISP编程绘制正弦曲线的问题，下面的程序到底错在哪里。老是提示number：nil 跪求！！！

(defun c:drawsin (/ lp lpx lpy n x step)
(initget 1)
(setq lp (getpoint "\n 输入坐标原点:")
lpx (car lp)
lpy (cadr lp)
)
(initget 7)
(setq n (getint "\n 周期数:"))
(setq a (getreal "\n 振幅:"))
(initget 1)
(setq w (getreal "\n 初相角(弧度):"))
(setq x 0
Steq 0.02
)
(command "pline")
(while (< x (* 2 n pi))
(command (list (+ (car lp) x)
(+ (cadr lp) (* a (sin (+ x w))))
)
)
(setq x (+ x step))
)
(command)
(command "line" lp (list (+ lpx (* 2 n pi)) lpy) " ")
(command "line"
(list lpx (+ lpy (* 2 a)))
(list lpx (- lpy (* 2 a)))
" "
)
(command "zoom" "e")
(princ)
)

Answer 1

变量Steq 0.02，下面的变量为setp，所以数值为nil。

(defun c:tes ( / #os1 a lp lpx lpy n steq w x)
 (setvar "cmdecho" 0)
 (setvar "blipmode" 0)
 (setq #os1 (getvar "osmode"));取得捕捉设置
 (if (and 
  (setq lp  (getpoint "\n 输入坐标原点:"))
  (setq lpx (car lp))
  (setq lpy (cadr lp))
  (setq n (getint "\n 周期数:"))
  (setq a (getreal "\n 振幅:"))
  (setq w (getreal "\n 初相角(弧度):"))
  (setq x 0 Steq 0.02)
  )
  (progn
   (setvar "osmode" 0);关闭捕捉绘制
   (command "pline")
   (while (< x (* 2 n pi))
    (command (list (+ (car lp) x)
    (+ (cadr lp) (* a (sin (+ x w))))))
    (setq x (+ x steq))
   )
   (command "")
   (command "line" lp (list (+ lpx (* 2 n pi)) lpy) "")
   (command "line"
    (list lpx (+ lpy (* 2 a)))
    (list lpx (- lpy (* 2 a)))
    ""
   )
   (command "zoom" "e")
   (setvar "osmode" #os1);还原捕捉设置
  )
 )
 (princ)
)