Question

这道vb代码怎么写

Answer 1

新建窗体，添加控件，各控件对应名称如下：

数据1  lblNum1  右文本框  txtNum1

数据2  lblNum2  右文本框  txtNum2

计算结果  lblResult  右文本框  txtResult

产生  cmdGenerate

加法  cmdAdd

减法  cmdMinus

清除  cmdClear

添加如下代码：

' -------------
' 枚举: 操作符.
' -------------
Private Enum MyOperators
    MO_ADD
    MO_MINUS
End Enum

' 生成.
Private Sub cmdGenerate_Click()
    Dim i%
    
    ' /* 循环生成 1~100 之间的随机整数并赋值给文本框. */
    For i = 1 To 2
        Controls("txtNum" & CStr(i)).Text = CStr(Int(100 * Rnd + 1))
    Next
    
    If Len(txtResult.Text) Then
        txtResult.Text = vbNullString
    End If
End Sub

' 加法
Private Sub cmdAdd_Click()
    txtResult.Text = CalcNum(txtNum1.Text, txtNum2.Text, MO_ADD)
End Sub

' 减法
Private Sub cmdMinus_Click()
    txtResult.Text = CalcNum(txtNum1.Text, txtNum2.Text, MO_MINUS)
End Sub

' 清除.
Private Sub cmdClear_Click()
    Dim ctrlTextBox As Control
    
    For Each ctrlTextBox In Controls
        If TypeOf ctrlTextBox Is TextBox Then
            If Len(ctrlTextBox.Text) Then
                ctrlTextBox.Text = vbNullString
            End If
        End If
    Next
End Sub

' ################################
' [功能描述] 根据操作符计算两个数.
' [参数列表] 1. Num1  第一个数;
'            2. Num2  第二个数.
' [返回类型] Variant.
' ################################
Private Function CalcNum(ByVal Num1 As Variant, _
                         ByVal Num2 As Variant, _
                         ByVal MO As MyOperators) As Variant
    
    On Error GoTo Err_CalcNum
    
    Select Case MO
        Case MO_ADD
            CalcNum = Val(Num1) + Val(Num2)
        Case MO_MINUS
            CalcNum = Val(Num1) - Val(Num2)
        Case Else
            GoTo Err_CalcNum
    End Select
    
    Exit Function
    
Err_CalcNum:
    CalcNum = "Error"
End Function

运行效果：