Question

批处理高手请进，帮忙解决难题

我在f盘公司文件夹内有个会议纪要文件夹，里面是我做的会议纪要.doc格式，第一份会议纪要名称为“会议纪要001.doc，做好后再复制一份并改名为“会议纪要001验证”，然后再建立一个文件夹，把两个.doc文档放进去，并将文件夹命名为“会议纪要001”，以后再做的话先从“会议纪要001”文件夹中将：将会议纪要001.doc复制出来放在F\公司文件\会议纪要文件夹中，然后就在这上面改改，完成后就命名为“会议纪要002”，然后再在像上面所说的那样建立文件夹，复制，移动，建立的文件夹名称就叫会议纪要002，以后以此类推了。
注意的是：每次复制的要是上一次做到会议纪要.doc，这样可保证最新版本格式！请大侠指教，我正在学习批处理，望能解释每一动作，测试成功后，增加100分，同时增加我对你的祝福！
简单讲：这句话表达要做的事情就是：复制、更名、建立文件夹、移动，但不是这么简单，要求是，1、复制.doc文档是复制上次刚做的（按修改时间排列这个文档应该排最后的那个），这个怎么编批处理，让批处理可以能找到？2、更名是要按顺序更名的，如上个会议名称叫“会议纪要001”这次就自动更名为：“会议纪要002.doc”，有：“会议纪要002.doc”时就自动更名为“会议纪要003.doc”以此类推？建立的文件命名也是这样的。（测试成功后，增加100分，同时增加我对你的祝福！）
我是刚学批处理：我上面的意思要用批处理做的事情是1、我要用的时候，点一个批处理可以复制出来一个最新编辑的.doc文档出来，且更名为会议纪要xxx.doc（xxx按顺序如001、002等）2、等我修改好后再点击一下批处理，可以按上面所说的建立个文件夹，复制、移动到该文件夹。我本人认为要用到两个批处理，不然1个批处理一直要开着，是能累死，懂了没？反正就是人性化的较少工作量，想把复制、移动、重命名这环节让批处理做啊！请各大大侠帮帮忙，写上批处理每一步注释，我想学！谢谢！

Answer 1

先和你说用法：
1、第一次使用先将所有会议纪要的文档设置为只读，然后把最新的会议纪要文档祛除只读；
2、放在 “会议纪要001(指文件夹)”的旁边运行；
操作：
① O选择会打开最新的会议纪要(复制到C盘打开,具体路径你自己改下)
② S则是你修改了会议纪要保存后应选择的项。

我测试成功了，但你路径不知道是不是有问题，我在桌面做的测试~~~有问题给我留言。

@echo off
set /p xz=O打开上次会议纪要,S保存到服务器:
if /i %xz%==o goto 1
if /i %xz%==s goto 2
cls & call %0

:1
del c:\上次会议纪要.doc /a /f
for /f "delims=" %%i in ('dir .\会议纪要*.doc /a-d-r/b/s^|^find /v "验证"') do (
copy "%%i" c:\上次会议纪要.doc && start "" c:\上次会议纪要.doc
)
cls & echo 已打开上次会议纪要 & pause & exit

:2
setlocal enabledelayedexpansion
attrib +r *会议纪要*.doc /s
for /f "delims=" %%k in ('dir .\*会议纪要* /ad/s^|^find "会议纪要" /c') do (
set /a k=%%k+1
if !k! lss 10 (
md 会议纪要00!k!
copy c:\上次会议纪要.doc 会议纪要00!k!\会议纪要00!k!.doc
copy c:\上次会议纪要.doc 会议纪要00!k!\会议纪要00!k!验证.doc
attrib -r 会议纪要00!k!\会议纪要00!k!.doc
) else (
if !k! lss 100 (
md 会议纪要0!k!
copy c:\上次会议纪要.doc 会议纪要0!k!\会议纪要0!k!.doc
copy c:\上次会议纪要.doc 会议纪要0!k!\会议纪要0!k!验证.doc
attrib -r 会议纪要0!k!\会议纪要0!k!.doc
) else (
if !k! lss 1000 (
md 会议纪要!k!
copy c:\上次会议纪要.doc 会议纪要!k!\会议纪要!k!.doc
copy c:\上次会议纪要.doc 会议纪要!k!\会议纪要!k!验证.doc
attrib -r 会议纪要!k!\会议纪要!k!.doc
))))
echo 保存到服务器完成 & pause

不能简化啊，晕。~~~

Answer 2

帮你写好了..
有几点要跟你说清楚.
1,我认为用001 002这些命名顺序的话呢给批处理的运算带来麻烦,而且效率也比较低,所以我想直接用1 2 3 这样就好,一直累加,应该对你的程序没什么影响的.所以就这样.
2,我帮你写好的文件opdoc.bat这个文件里面直接是复制上次保存的ODC文件出来，然后打开让你编辑,所以你最少要在自己的"会议纪要"文件夹下建立一个"会议纪要1",不然程序运行不了,那你会问我为什么不写判断,因为没必要，你这个要长期用的，不可能没有那些文件夹,所以省去判断...
3.我系统上无装WORD系统,所以里面我是用TXT文本格式来测试的，自己把批处理的TXT都改成DOC就OK啦..
4,把两个批处理文件放到你说的"F:\公司文件\会议机要\"文件夹下面就OK..恩..
5.记得别动"文件变量.txt"这个是记录每次复制过来的文件名称,所以你留在目录下，别动就好
附上两个文件的代码:

============opdoc.bat===============
@echo off
rem 此批处理是复制最近一次修改的DOC文件到会议机要文件夹，然后打开编辑
for /f "delims=" %%a in ('dir /b/ad/tw') do set fzwjj=%%a

copy "%fzwjj%\%fzwjj%.txt"
echo %fzwjj%>>文件变量.txt
start "" "%fzwjj%\%fzwjj%.txt"
exit

============cjdoc.bat================
@echo off
rem 将会议机要文件夹下的刚编辑好的文件保存到新文件夹中，并复制备份文件
for /f "delims=" %%a in (文件变量.txt) do set fzwj=%%a
set n=%fzwj:~4%
set /a n+=1

md "会议纪要%n%"
copy "%fzwj%.txt" "会议纪要%n%\会议纪要%n%.txt"
copy "%fzwj%.txt" "会议纪要%n%\会议纪要%n%验证.txt"
del /q "%fzwj%.txt"
echo 创建文件夹完成!按任意键退出
pause>nul&exit

Answer 3

20分？