Question

WORD. VBA: 如何给指定文件夹内部所有DOC文件的内容最后加上一段文字？

Answer 1

Option Explicit
Sub a()
   ' On Error Resume Next
    Dim sFolderFullPath As String
    Dim oFiles As Collection
    Dim lFileIndex As Long
    Dim sFileFullName As String, sFileName As String
    Dim oDoc As Word.Document
    Dim lDocCount As Long
    
    Const addText = "text" & vbCrLf & "此份文档能够解析大型的DBX文件。在大型的DBX文件中无法找到邮件表连接的规律，或则在认识上还存在问题，但只要按照文档阐述的方法去解析，是可以完整解析的。"  '添加的文本
    
    '选择文件夹
    With Application.FileDialog(msoFileDialogFolderPicker)
        .AllowMultiSelect = False
        .Title = "请选择文件夹"
        .Show
        If .SelectedItems.Count = 0 Then
            MsgBox "您没有选择一个文件夹，程序将退出！"
            Exit Sub
        End If
        sFolderFullPath = .SelectedItems.Item(1)
    End With
    
    sFileName = Dir(sFolderFullPath & "\*.doc*", vbNormal)
    
    While Len(sFileName) > 0
        sFileFullName = sFolderFullPath & "\" & sFileName
        Set oDoc = Documents.Open(sFileFullName)
        If Not oDoc Is Nothing Then
            oDoc.Content.InsertParagraphAfter   '在文档最后添加一个新的段落，
            oDoc.Paragraphs.Last.Alignment = wdAlignParagraphLeft  '左对齐
            
            oDoc.Paragraphs.Last.Range.Select
            Selection.Text = addText        '将心段落的文字设置为 。。。
            Selection.EndKey        '将插入点移到文档尾部
            'odoc.Save   '保存文档
        End If
        sFileName = Dir  '枚举下一个
    Wend
End Sub

Answer 2

你这个现在自己写到什么程度了？