Question

两个关于批处理的问题

1.在批处理中怎么让这个命令一直处于监控状态（一直执行到成功为止）？
if exist f:\sss\rr.swf (del f:\sss\uu.swf)
2.怎么让命令在后台执行？

Answer 1

1、
加个时间吧，可以这样写：
@echo off
:go
if exist f:\sss\rr.swf del f:\sss\uu.swf & exit
ping -n 5 127.1>nul
goto go
表示5秒检查1次~~~

2、
（1）同楼上的，
set objShell = CreateObject( WScript.Shell)
a = objShell.Run("d:\loop.bat",0)
（2）高手用，
在批处理前加入以下代码：
实际是调用vbs语言后台运行批处理，只有进程中才看的到.
@echo off
if "%1"=="h" goto begin
start mshta vbscript:createobject("wscript.shell").run("""%~nx0"" h",0)(window.close)&&exit
:begin

3、这个应该是你最终的目的：
@echo off
if "%1"=="h" goto begin
start mshta vbscript:createobject("wscript.shell").run("""%~nx0"" h",0)(window.close)&&exit
:begin
:go
if exist f:\sss\rr.swf del f:\sss\uu.swf & exit
ping -n 5 127.1>nul
goto go

嘿嘿，如果对你有帮助，加点飞哦。。。

Answer 2

让命令一直处于监视状态的方法有2个:
第一个是实现一个死循环的命令来执行；
第二个方法是使用goto 标记 的方法来运行。

这2个方法都需要在批处理里实现，而不能直接使用DOS命令来实现;

2,让命令在后台执行:

目前我知道的2种方法是:

1,通过DOS命令 AT 来添加计划任务的方法执行BAT文件；
2,把批处理编译出来， 有一个程序叫battoexe(大概是这个，忘记了) ,可以把BAT编译成EXE程序,并且隐藏运行。你可以搜索一下。

Answer 3

1.用goto或者for语句做成死循环，删除掉再退出
:loop
if exist f:\sss\rr.swf (
del f:\sss\uu.swf
exit
)
goto:loop
不过其实这样做效果不是太好，会占用很多系统资源

2.批处理本身无法在后台执行，必须借助vbs
假设你的批处理是d:\loop.bat
把下面语句写成.vbs
set objShell = CreateObject( WScript.Shell)
a = objShell.Run("d:\loop.bat",0)

Answer 4

1、a.vbs(系统后台隐藏运行b.bat)
createObject("wscript.shell").run "b.bat",0
2、b.bat(放在同级目录)(加了一个延时，5秒判断一次，要不怕你电脑会不好受)
:loop
ping 127.1 -n 5
if exist f:\sss\rr.swf (del f:\sss\uu.swf)
goto loop

Answer 5

这是什么呢？