Question

bat先查找文件夹再查找文件夹内的文件并打开

比如我要查找ABC文件夹，但是我不知道ABC文件夹在哪个盘哪个文件夹里，找到这个文件夹之后再找文件夹内的123.exe程序，这个123.exe程序也不知道在哪个子文件夹内，找到后打开这个程序！

Answer 1

批处理（bat）实现全盘搜索指定文件获取其完整路径方法大全
废话不多说，直接上代码，额，想用的话，自己保存成bat文件即可。
【方案一】for /f + dir

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)

【方案二】for /r（比 for /f + dir 效率高，但不会遍历隐藏文件）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
pushd %%a:\
for /r %%b in (*%FileName%) do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
popd
)
)

【方案三】WMIC（Win2000/WinXP HOME版、WinXP 精简版可能不支持）

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in ("%FileName%") do (
set "nName=%%~na"
set "xName=%%~xa"
)
set "xName=%xName:~1%"
for /f "skip=1 delims=" %%a in ('wmic datafile where "filename='%nName%' and Extension='%xName%'" get name') do (
echo,%%a
)

【方案四】使用 Windows7 系统自带的 where 命令

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
for /f "delims=" %%b in ('where /r %%a: "%FileName%" 2^>nul') do (
if /i "%%~nxb" equ "%FileName%" (
echo,%%b
)
)
)
)

打开文件的代码：
bat如何查找指定目录下含有关键字的文件夹并打开
@echo off
set /p folder=请输入文件夹关键字
for /f "delims=" %%a in ('dir /ad /b /s D:\Report') do (
echo %%a|find "%folder%" >nul &&(start "" "%%~a"&exit)
)

以上供你参考。能力有限，你自己看着捣鼓吧

Answer 2

如果是win系统的话直接使用查找就可以了，如果是你想用bat命令来查找的话可以用dir 123.exe/s就可以了，当然先转到某个盘中去。
例如：
C：
cd\
dir 123.exe/s

D：
cd\
dir 123.exe/s

追问

我是说批处理，不是命令指示符，因为这个程序在其他文件夹内也会有，所有我要先找到一个特定的文件夹再去查找这个程序

追答

你可以建立一个bat文件，内容中加入前面的命令，然后运行bat文件是可以找到123.exe所在的文件夹的（会显示文件夹名称的）

追问