Question

请大神帮忙做个批处理，要求如下： 同时ping3个IP地址并分别保存在3个文本文档，每个文档都有时间段

例如：同时ping 192.168.1.100 192.168.1.101 192.168.1.102这3个IP地址，并且分别保存在1.txt,2.txt,3.txt，并且每个文本文档里面都有ping此IP地址的时间段
万分感激。
我是用start cmd /c ping 192.168.1.100 -t >1.txt
start cmd /c ping 192.168.1.101 -t >2.txt
start cmd /c ping 192.168.1.102 -t >3.txt
这个命令，但是ping的结果无法保存在文本文档里。
如果用：ping 192.168.1.100 -t >1.txt
ping 192.168.1.100 -t >1.txt
ping 192.168.1.100 -t >1.txt
这个命令，虽然可以保存在文本文档，但是不可以同时进行，求大神帮忙，感激。

Answer 1

start "" cmd /c "echo 正在 ping 192.168.1.100&(ping 192.168.1.100 -t)>1.txt"
start "" cmd /c "echo 正在 ping 192.168.1.101&(ping 192.168.1.101 -t)>2.txt"
start "" cmd /c "echo 正在 ping 192.168.1.102&(ping 192.168.1.102 -t)>3.txt"

追问

你好，非常感谢，用你的方法成功了，不过我想问下，如何在里面加上ping的起止时间或者就是每次ping的时间，谢谢。

Answer 2

要加start的，>符前要加转义符^ 表示此符是传给另一cmd的，如

start/min cmd /c ping 192.168.1.100 -t ^>1.txt

追问

你好，非常感谢，用你的方法成功了，不过我想问下，如何在里面加上ping的起止时间或者就是每次ping的时间，谢谢。

追答

可以作到，原理是将ping -t 的改为每次显示时间再ping一次，并无限循环
最好你先在命令行按以下代码作一个IP的测试截图给我看看，并给个希望写入文件的格式(可以把某些行不写入文件)
for %i in (1,1)do @echo 时间%time%&ping /n 1 192.168.1.100

追问

你好，用上面的代码测试，一闪就没了，灭有弹出对话框，看不到结果。

追答

哎，本来想在 命令行 测试要简单点(如此命令写到批处理运行肯定一闪而过)，之所以想看看截图是因为不同系统ping出来的格式不完全相同，想选出其中具某特征串的行写入文件，下面我就写一个，是只找具有"Reply"串的行的.估计你能根据需要自己更改（写的大于等于12时自动结束，如要无限循环把那句去掉就行了）

@echo off
if "%1"=="" goto :main
title %1
echo =============%date:~,10%==============>%1.txt
:ff
if "%time%" geq "12:" exit
(set/p=%time% <nul
ping -n 1 %1|find "Reply")>>%1.txt
goto :ff
:main
set IPs=192.168.1.100 192.168.1.101 192.168.1.102
for %%i in (%IPs%)do start/min "" "%~0" %%i