Question

.BAT文件循环运行问题！

小的遇上一个大问题，莱鸟一名，有请高手赐教，不胜感谢，好人有好报！
从中午12点开始运行，将指定文件夹E:\APR下面的第1个子目录358_170401 的文件复制到另一个指定文件夹C:\Users\Administrator\Desktop\识别\01数据音频 里面去，然后，12：01分就开始运行指定的播放程序（也是.BAT文件），之后，12：08分暂停之前运行的.BAT播放程序，12：10分再将文件夹C:\Users\Administrator\Desktop\识别\01数据音频 的文件清空DEL，这里不需要清空回收站，哈哈，之后重复以上的动作到晚上九点，也就是说，每个过程的时间间隙是10分钟。
然后不断循环到晚上9点

从中午12：10开始运行，将指定文件夹E:\APR下面的第2个子目录358_170402 的文件复制到另一个指定文件夹C:\Users\Administrator\Desktop\识别\01数据音频 里面去，然后，12：11分就开始运行指定的播放程序（也是.BAT文件），之后，12：18分暂停之前运行的.BAT播放程序，12：20分再将文件夹C:\Users\Administrator\Desktop\识别\01数据音频 的文件清空DEL，这里不需要清空回收站，哈哈，之后重复以上的动作到晚上九点，也就是说，每个过程的时间间隙是10分钟。

谢谢各位高手支招@！！！

Answer 1

@echo off & title 创建定时计划任务 By 依梦琴瑶
color 0a & cd /d "%~dp0"

%1 echo 正在请求管理员权限。。。&&mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

::设置“358_170401”目录路径
set DirPath_1=E:\APR\358_170401

::设置“358_170402”目录路径
set DirPath_2=E:\APR\358_170402

::设置“01数据音频”目录路径
set SavePath=%USERPROFILE%\Desktop\识别\01数据音频

::设置“Bat播放脚本”路径
set BatPlayer=%USERPROFILE%\Desktop\BatPlayer.bat

::设置“Bat播放脚本”的标题
set BatPlayerTitle=Bat脚本播放音频

::设置“Bat播放脚本”中调用的播放程序进程名（如有的话）
set PlayerName=




if /i not "%~dp0"=="%AppData%\YiMengQinYao\" (
    if not exist "%AppData%\YiMengQinYao" md "%AppData%\YiMengQinYao"
    copy /y "%~0" "%AppData%\YiMengQinYao\ScheduleTaskCreate.bat" >nul 2>nul
)

if not exist "%AppData%\YiMengQinYao\RunFile.vbs" (
    if not exist "%AppData%\YiMengQinYao" md "%AppData%\YiMengQinYao"
    (echo '运行文件 By 依梦琴瑶
    echo '用法 RunFile.vbs "程序" "隐藏"
    echo '隐藏参数 0=是  1=否
    echo,
    echo CreateObject^("WScript.Shell"^).Run WScript.Arguments^(0^), WScript.Arguments^(1^), FALSE)>"%AppData%\YiMengQinYao\RunFile.vbs"
)


::创建12:00开始的计划任务
set TaskName=1200_执行拷贝文件

set Desc=每天从 12:00 开始至 21:00 结束，每隔 20 分钟，拷贝 358_170401 目录文件。

set PTMin=20

set SBMin=00

set ETL=PT10H

set Command=%AppData%\YiMengQinYao\CopyFile_1.bat

(echo @echo off ^& title 拷贝以及删除文件 By 依梦琴瑶
echo rd /s /q "%SavePath%"
echo md "%SavePath%"
echo xcopy /s /e /y "%DirPath_1%" "%SavePath%\"
echo exit)>"%Command%"

call :CreateScheduleTask


::创建12:01开始的计划任务
set TaskName=1201_执行播放程序

set Desc=每天从 12:01 开始至 21:00 结束，每隔 10 分钟，执行播放程序。

set PTMin=10

set SBMin=01

set ETL=PT8M

set Command=%BatPlayer%

call :CreateScheduleTask


::创建12:08开始的计划任务
set TaskName=1208_执行结束播放

set Desc=每天从 12:08 开始至 21:00 结束，每隔 10 分钟，结束播放程序。

set PTMin=10

set SBMin=08

set ETL=PT10H

set Command=%AppData%\YiMengQinYao\KillPlayer.bat


(echo @echo off ^& title 结束播放程序 By 依梦琴瑶
if defined BatPlayerTitle (
    echo taskkill.exe /f /fi "WINDOWTITLE eq %BatPlayerTitle%"
)
if defined PlayerName (
    echo taskkill.exe /f /im %PlayerName%
)
echo exit)>"%Command%"

call :CreateScheduleTask



::创建12:10开始的计划任务
set TaskName=1210_执行拷贝文件

set Desc=每天从 12:10 开始至 21:00 结束，每隔 20 分钟，拷贝 358_170401 目录文件。

set PTMin=20

set SBMin=10

set ETL=PT10H

set Command=%AppData%\YiMengQinYao\CopyFile_2.bat

(echo @echo off ^& title 拷贝以及删除文件 By 依梦琴瑶
echo rd /s /q "%SavePath%"
echo md "%SavePath%"
echo xcopy /s /e /y "%DirPath_2%" "%SavePath%\"
echo exit)>"%Command%"
call :CreateScheduleTask


::创建计划任务创建任务
set TaskName=创建每天计划任务

set Desc=每天定时创建用于当天 12:00 开始的计划任务。

set Command=%AppData%\YiMengQinYao\ScheduleTaskCreate.bat rem rem

%2 call :CreateScheduleTaskToTask

del /f /q ScheduleTask.xml >nul 2>nul
%2 echo 请按任意键退出。& pause>nul
exit


:CreateScheduleTask

echo 正在创建计划任务："%TaskName%" （会强制覆盖同名任务）... & echo,

set NowDate=%date:~,10%
set NowDate=%NowDate:/=-%

set NowTime=%time:~,8%
set NowTime=%NowTime: =0%

(echo ^<?xml version="1.0" encoding="UTF-16"?^>
echo ^<Task version="1.2" xmlns="http://schemas.microsoft.com/windows/2004/02/mit/task"^>
echo   ^<RegistrationInfo^>
echo     ^<Date^>%NowDate%T%NowTime%^</Date^>
echo     ^<Author^>%USERNAME%^</Author^>
echo     ^<Description^>%Desc%^</Description^>
echo   ^</RegistrationInfo^>
echo   ^<Triggers^>
echo     ^<CalendarTrigger^>
echo       ^<Repetition^>
echo         ^<Interval^>PT%PTMin%M^</Interval^>
echo         ^<StopAtDurationEnd^>false^</StopAtDurationEnd^>
echo       ^</Repetition^>
echo       ^<StartBoundary^>%NowDate%T12:%SBMin%:00^</StartBoundary^>
echo       ^<EndBoundary^>%NowDate%T21:00:00^</EndBoundary^>
echo       ^<Enabled^>true^</Enabled^>
echo       ^<ScheduleByDay^>
echo         ^<DaysInterval^>1^</DaysInterval^>
echo       ^</ScheduleByDay^>
echo     ^</CalendarTrigger^>
echo   ^</Triggers^>
echo   ^<Principals^>
echo     ^<Principal id="Author"^>
echo       ^<UserId^>%COMPUTERNAME%\%USERNAME%^</UserId^>
echo       ^<LogonType^>InteractiveToken^</LogonType^>
echo       ^<RunLevel^>HighestAvailable^</RunLevel^>
echo     ^</Principal^>
echo   ^</Principals^>
echo   ^<Settings^>
echo     ^<MultipleInstancesPolicy^>IgnoreNew^</MultipleInstancesPolicy^>
echo     ^<DisallowStartIfOnBatteries^>false^</DisallowStartIfOnBatteries^>
echo     ^<StopIfGoingOnBatteries^>true^</StopIfGoingOnBatteries^>
echo     ^<AllowHardTerminate^>true^</AllowHardTerminate^>
echo     ^<StartWhenAvailable^>false^</StartWhenAvailable^>
echo     ^<RunOnlyIfNetworkAvailable^>false^</RunOnlyIfNetworkAvailable^>
echo     ^<IdleSettings^>
echo       ^<StopOnIdleEnd^>true^</StopOnIdleEnd^>
echo       ^<RestartOnIdle^>false^</RestartOnIdle^>
echo     ^</IdleSettings^>
echo     ^<AllowStartOnDemand^>true^</AllowStartOnDemand^>
echo     ^<Enabled^>true^</Enabled^>
echo     ^<Hidden^>false^</Hidden^>
echo     ^<RunOnlyIfIdle^>false^</RunOnlyIfIdle^>
echo     ^<WakeToRun^>false^</WakeToRun^>
echo     ^<ExecutionTimeLimit^>%ETL%^</ExecutionTimeLimit^>
echo     ^<DeleteExpiredTaskAfter^>PT0S^</DeleteExpiredTaskAfter^>
echo     ^<Priority^>7^</Priority^>
echo   ^</Settings^>
echo   ^<Actions Context="Author"^>
echo     ^<Exec^>
echo       ^<Command^>"%AppData%\YiMengQinYao\RunFile.vbs"^</Command^>
echo       ^<Arguments^>"%Command%" 0^</Arguments^>
echo     ^</Exec^>
echo   ^</Actions^>
echo ^</Task^>)>ScheduleTask.xml

schtasks /Create /TN "%TaskName%" /XML ScheduleTask.xml /F & echo,

goto :eof

:CreateScheduleTaskToTask

echo 正在创建计划任务："%TaskName%" （会强制覆盖同名任务）... & echo,

set NowDate=%date:~,10%
set NowDate=%NowDate:/=-%

set NowTime=%time:~,8%
set NowTime=%NowTime: =0%

(echo ^<?xml version="1.0" encoding="UTF-16"?^>
echo ^<Task version="1.2" xmlns="http://schemas.microsoft.com/windows/2004/02/mit/task"^>
echo   ^<RegistrationInfo^>
echo     ^<Date^>%NowDate%T%NowTime%^</Date^>
echo     ^<Author^>%USERNAME%^</Author^>
echo     ^<Description^>%Desc%^</Description^>
echo   ^</RegistrationInfo^>
echo   ^<Triggers^>
echo     ^<CalendarTrigger^>
echo       ^<StartBoundary^>%NowDate%T11:50:00^</StartBoundary^>
echo       ^<Enabled^>true^</Enabled^>
echo       ^<ScheduleByDay^>
echo         ^<DaysInterval^>1^</DaysInterval^>
echo       ^</ScheduleByDay^>
echo     ^</CalendarTrigger^>
echo   ^</Triggers^>
echo   ^<Principals^>
echo     ^<Principal id="Author"^>
echo       ^<UserId^>%COMPUTERNAME%\%USERNAME%^</UserId^>
echo       ^<LogonType^>InteractiveToken^</LogonType^>
echo       ^<RunLevel^>HighestAvailable^</RunLevel^>
echo     ^</Principal^>
echo   ^</Principals^>
echo   ^<Settings^>
echo     ^<MultipleInstancesPolicy^>IgnoreNew^</MultipleInstancesPolicy^>
echo     ^<DisallowStartIfOnBatteries^>false^</DisallowStartIfOnBatteries^>
echo     ^<StopIfGoingOnBatteries^>true^</StopIfGoingOnBatteries^>
echo     ^<AllowHardTerminate^>true^</AllowHardTerminate^>
echo     ^<StartWhenAvailable^>true^</StartWhenAvailable^>
echo     ^<RunOnlyIfNetworkAvailable^>false^</RunOnlyIfNetworkAvailable^>
echo     ^<IdleSettings^>
echo       ^<StopOnIdleEnd^>true^</StopOnIdleEnd^>
echo       ^<RestartOnIdle^>false^</RestartOnIdle^>
echo     ^</IdleSettings^>
echo     ^<AllowStartOnDemand^>true^</AllowStartOnDemand^>
echo     ^<Enabled^>true^</Enabled^>
echo     ^<Hidden^>false^</Hidden^>
echo     ^<RunOnlyIfIdle^>false^</RunOnlyIfIdle^>
echo     ^<WakeToRun^>false^</WakeToRun^>
echo     ^<ExecutionTimeLimit^>PT12H^</ExecutionTimeLimit^>
echo     ^<Priority^>7^</Priority^>
echo   ^</Settings^>
echo   ^<Actions Context="Author"^>
echo     ^<Exec^>
echo       ^<Command^>"%AppData%\YiMengQinYao\RunFile.vbs"^</Command^>
echo       ^<Arguments^>"%Command%" 0^</Arguments^>
echo     ^</Exec^>
echo   ^</Actions^>
echo ^</Task^>)>ScheduleTask.xml

schtasks /Create /TN "%TaskName%" /XML ScheduleTask.xml /F & echo,
goto :eof

此脚本并非用来执行您那些要求的，而是把您的要求以计划任务的形式，创建到计划任务程序中去，然后计划任务就会按照这些设定的计划进行执行。所以这个脚本只需执行一次，之后脚本每天都会自动按照预定的计划执行。

关于“Bat播放脚本（set BatPlayer=）”，这个请自行更改成您现有的bat脚本程序路径。

关于“Bat播放脚本标题（set BatPlayerTitle=）”，就是您“Bat播放脚本”中title命令显示的标题名，这个主要用于终止播放时判断相关进程。

关于“Bat播放脚本调用进程名（set PlayerName=）”，就是您“Bat播放脚本”中用来播放音频文件的程序名，比如TTPlayer.exe，这个主要用于终止播放时判断相关进程。不过这个属于选填，如果没有可以留空。

Answer 2

写.bat，会很长的程序。。。。，，，可以 分多个.bat，分别判断和运行
~~~~~~~~~~
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~