Question

flash怎样实现直线一端固定，另一端绕一定路径运动？

Answer 1

另一端绕一定路径运动？这不恰似时针旋转吗？这里的数学知识点是，如何求出两点间连线的角度。那么在as3.0中代码能实现吗？必需的。

写一个actionsprit 3.0类文档：

package 
{

	public class angle
	{

		//静态访问功能：角度转弧度
		public static function angleToRadian(angle:Number):Number
		{
			return angle*Math.PI /180;//返回弧度的值
		}
		//静态访问功能：弧度转角度
		public static function radianToAngle(radian:Number ):Number
		{
			return radian*180/Math.PI;//返回角度值
		}
		//求两点间连线角度
		public static function towPointGetAngle(x1:Number ,y1:Number,x2:Number ,y2:Number ):Number
		{
			var dx = x2 - x1;//求出x轴方向距离
			var dy = y2 - y1;//求出Y轴方向距离
			var radian:Number = Math.atan2(dy,dx);//反正切函数求出弧度值
			return angle.radianToAngle(radian);//返回角度值。
		}
	}

}

看了上面的实例相信你对两点间连线的角度在as中实现有了一定的了解，下面我们来看一下，怎么运用它。

1，新建一个actionsprit3.0文档，保存在上面类文档同一个文件夹里面儿。

2，插入--新建元件--影片剪辑。如图：所有属性设置请图一样。

在库中看到它是绿色的。

3，在剪辑（line）图层1第1帧，任意画一条直线。锁定图层。

4，点击第一张图中，类(c)后面的小铅笔，为剪辑（line）绑定一个类文档，保存新建的类文档在fla文件同一文件夹。

5，剪辑（line）的绑定类文档代码如下：

package 
{

	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;


	public class line extends Sprite
	{


		public function line()
		{
			addEventListener(Event.ENTER_FRAME,lineRotate);//帧频侦听器
		}
		private function lineRotate(e:Event ):void
		{
			var lineGlobal:Point = this.parent.localToGlobal(new Point(x,y));//局部坐标转全局坐标。
			this.rotation = angle.towPointGetAngle(lineGlobal.x,lineGlobal.y,stage.mouseX,stage.mouseY);//计算旋转角度
		}
	}

}

6，全部保存，测试没有效果时告诉我！

Answer 2

用遮罩就可以了

Answer 3

这个应该不难吧我可以试试