Question

怎样改变listview中listitem的字体颜色

Answer 1

一、改变颜色

在VB6的ListView控件中，可以改变项目及其子项的前景色、背景色。实现方法如下
（1）在窗体上布置一个ListView控件

（2）窗体代码如下

Option Explicit

Private Sub Form_Load()
Dim itemX As ListItem

With ListView1
.View = lvwReport

.ColumnHeaders.Add , , "类别"
.ColumnHeaders.Add , , "品名1"
.ColumnHeaders.Add , , "品名2"

Set itemX = .ListItems.Add(, , "水果")
itemX.SubItems(1) = "苹果"
itemX.SubItems(2) = "香蕉"
ChangeForeColor itemX, &H8000& '墨绿色

Set itemX = .ListItems.Add(, , "饮料")
itemX.SubItems(1) = "果汁"
itemX.SubItems(2) = "可乐"
ChangeForeColor itemX, vbRed '红色

Set itemX = .ListItems.Add(, , "文具")
itemX.SubItems(1) = "铅笔"
itemX.SubItems(2) = "橡皮"
ChangeForeColor itemX, vbBlue '蓝色

End With
End Sub

'-------------------------------------
' 修改ListView 项的前景色颜色
'-------------------------------------
Private Sub ChangeForeColor( _
ByVal item As ListItem, _
ByVal NewColor As Long)
'设置项的颜色
item.ForeColor = NewColor
'设置所有子项的颜色
Dim subItem As ListSubItem
For Each subItem In item.ListSubItems
subItem.ForeColor = NewColor
Next
End Sub

（3）运行效果

二、改变字体
ListView控件中，ListItem以及ListSubItem中没有字体属性，所以无法改变单独某个项或子项的字体；只能改ListView控件的字体。

运行效果