Question

vbs或bat批处理器映射网络驱动器的问题

目前公司部署了一台文件服务器，服务器已配置完成，现在需要将服务器上待共享的数据映射的员工的本地电脑上作为网络驱动器，公司电脑数量比较多，如果逐台去映射，工作量较大，想整个vbs或者bat的批处理器，运行批处理器后自动将网络驱动器映射到本地电脑，网上也找了不少数据，由于对这个代码不是很理解，老是不成功，望大虾指教

每个人的电脑上需要映射两个驱动器
1、\\ip\部门共享数据文件夹
2、\\IP\个人文件夹

代码中需要带用户名密码参数

谢谢

Answer 1

手上没有局域网的电脑，所以不怎么研究这类的批处理。

以下代码是需要去每台电脑上手动执行的代码：

@echo off & setlocal enabledelayedexpansion
title 映射网络共享 By 依梦琴瑶 & color 0a

::设置服务器IP地址
set IP=192.168.1.100

::设置服务器共享文件夹名字（PS）和映射后显示的卷标别名（PV）
set PS1=部门共享数据文件夹
set PV1=部门共享数据

set PS2=个人文件夹
set PV2=个人数据

::设置用户密码，没有就留空
set UPWD=

::以下代码请勿随意更改
set Num=0
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if not exist %%a:\ (
        set /a Num+=1
        set Pan!Num!=%%a
    )
    if !Num! equ 2 goto Mapping
)
exit

:Mapping
net use %Pan1%: \\%IP%\%PS1% "%UPWD%" /user:"%USERNAME%"
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%IP%#%PS1%" /v _LabelFromReg /d "%PV1%" /f

net use %Pan2%: \\%IP%\%PS2% "%UPWD%" /user:"%USERNAME%"
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##%IP%#%PS2%" /v _LabelFromReg /d "%PV2%" /f
echo, & echo 映射完毕，请按任意键退出
pause>nul & exit

效果图：

这个脚本中用户名可以不用设置，因为它会自动获取当前电脑的用户名。唯一缺点就是密码需要你对应电脑设置后，在每台电脑上运行一次。

如果在你服务器上直接运行一次，就给局域网内所有的电脑都映射，这个我还在研究，毕竟不怎么接触网络共享这一块的脚本代码。

追答

那个%USERNAME%这个变量，可能是错误的，使用的是服务器的用户名而不是当前本机的用户名。

所以前面，设置变量的地方添加一个

::设置服务器用户名
set USERNAME=

因此那个用户密码应该也是填服务器的用户密码。