Question

如何提取文件夹内特定扩展名文件名的部分字段到EXCEL

如图，例如在文件下，我只需要后缀PDF文件的文件名中的6个数字，把他们全部列举到一个EXCEL中
最好能用批处理的方式实现

Answer 1

答：可以使用程序来把指定文件夹里的PDF文件名全部读到工作表中来，然后对这些名字进行整理。

方法：

1、新建一个Excel工作簿，然后按ALT+F11，打开VB编辑器，“插入”一个“模块”，复制下面代码进去：

Private Sub ListPDF()
    Dim strFileName As String
    Dim strNames() As String
    Dim i As Long
    Dim FolderString As String
    Dim Desrange As Range
    
    Set Desrange = Range("A1")
    FolderString = GetDirectory
    If FolderString = "" Then Exit Sub
    strFileName = Dir(FolderString & "\*.pdf")
    Do Until strFileName = ""
        i = i + 1
        ReDim Preserve strNames(1 To i)
        strNames(i) = strFileName
        strFileName = Dir
    Loop
    If i = 0 Then
        MsgBox "没找到文件", vbExclamation, "提示"
        Exit Sub
    End If
    Desrange.Resize(i, 1).Value = Application.Transpose(strNames)
    MsgBox "共计" & i & "个文件", vbInformation, "提示"
End Sub
Private Function GetDirectory()
    Dim fd As FileDialog
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
    With fd
        If .Show = -1 Then
            GetDirectory = .SelectedItems(1)
        Else
            GetDirectory = ""
        End If
    End With
End Function

执行“ListPDF”这个程序，然后你所选定文件夹里的PDF文件名都列到A1开始的单元格中了。

2、至于取前面6个数字，用left函数即可取出。

Answer 2

详细操作步骤见下面的动画：