Question

易语言窗口最大化问题

我要做一个窗口最大化后组件跟着变大的源码，不过不能用，请高手看看
-------程序----------
.版本 2
.子程序 初始化组件, , 公开
.参数 父窗口, 窗口
.局部变量 窗口句柄, 整数型
窗口句柄 ＝ 父窗口.取窗口句柄 ()
_父窗口 ＝ 父窗口
枚举所有子窗体 (窗口句柄, &记录组件, 窗口句柄)
.子程序 窗口尺寸改变, , 公开
.局部变量 计次变量, 整数型
.计次循环首 (取数组成员数 (组件底边距离), 计次变量)
设置窗口位置 (_组件句柄 [计次变量], 0, 组件横坐标 [计次变量], 组件纵坐标 [计次变量], _父窗口.取用户区宽度 () － 组件右边距离 [计次变量], _父窗口.取用户区高度 () － 组件底边距离 [计次变量], 0)
.计次循环尾 ()
-----------------
.版本 2
.子程序 记录组件, 逻辑型
.参数 组件句柄, 整数型
.局部变量 矩形, 矩形
.局部变量 个数, 整数型, 静态
个数 ＝ 个数 ＋ 1
重定义数组 (组件底边距离, 真, 个数)
重定义数组 (组件右边距离, 真, 个数)
重定义数组 (_组件句柄, 真, 个数)
重定义数组 (组件横坐标, 真, 个数)
重定义数组 (组件纵坐标, 真, 个数)
重定义数组 (组件高度, 真, 个数)
重定义数组 (组件宽度, 真, 个数)
取窗口矩形 (组件句柄, 矩形)
_组件句柄 [个数] ＝ 组件句柄
组件底边距离 [个数] ＝ _父窗口.取用户区高度 () － 矩形.右边
组件右边距离 [个数] ＝ _父窗口.取用户区宽度 () － 矩形.底边
组件横坐标 [个数] ＝ 矩形.左边
组件纵坐标 [个数] ＝ 矩形.顶边
组件高度 [个数] ＝ 矩形.底边 － 矩形.顶边
组件宽度 [个数] ＝ 矩形.右边 － 矩形.左边
返回 (真)

---------全局变量-----------
.版本 2
.全局变量 组件底边距离, 整数型, , "0"
.全局变量 组件右边距离, 整数型, , "0"
.全局变量 _组件句柄, 整数型, , "0"
.全局变量 组件横坐标, 整数型, , "0"
.全局变量 组件纵坐标, 整数型, , "0"
.全局变量 组件高度, 整数型, , "0"
.全局变量 组件宽度, 整数型, , "0"
----------------dll命令---------------------------
.版本 2
.DLL命令 设置窗口位置, 整数型, "user32.dll", "SetWindowPos"
.参数 窗口句柄, 整数型
.参数 定位类型, 整数型
.参数 窗口新横坐标, 整数型
.参数 窗口新纵坐标, 整数型
.参数 窗口新宽度, 整数型
.参数 窗口新高度, 整数型
.参数 显示方式, 整数型

Answer 1

.版本 2
.程序集 窗口移动类, , 公开
.程序集变量 窗口句柄数组, 整数型, , "0"
.程序集变量 窗口比例, 窗口比例, , "0"
.程序集变量 顶级句柄, 整数型
.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用

.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用

.子程序 初始化, 整数型, 公开, 非零表示成功，零表示失败。
.参数 窗口句柄, 整数型, , 要初始化的顶级句柄
.局部变量 a, 整数型
.局部变量 顶级矩形坐标, 矩形坐标
.局部变量 临时矩形坐标, 矩形坐标
.局部变量 临时窗口比例, 窗口比例
.局部变量 宽度_, 整数型
.局部变量 高度_, 整数型
.局部变量 坐标, 坐标型
.局部变量 临时数组1, 整数型, , "0"
.局部变量 b, 整数型
.局部变量 c, 整数型
.局部变量 临时数组2, 整数型, , "0"
顶级句柄 ＝ 窗口句柄
取窗口内大小 (顶级句柄, 宽度_, 高度_)
_窗口取外边框 (顶级句柄, 顶级矩形坐标)
坐标 ＝ 取窗口内顶点 (顶级句柄)
' 调试输出 (坐标.x, 坐标.y, 顶级矩形坐标.矩形顶边, 顶级矩形坐标.矩形左边)
清除数组 (窗口比例)
.计次循环首 (枚举子窗口 (顶级句柄, 临时数组1), a)
.计次循环首 (枚举子窗口 (临时数组1 [a], 窗口句柄数组), b)
.计次循环首 (取数组成员数 (临时数组1), c)
.如果真 (临时数组1 [c] ＝ 窗口句柄数组 [b])
临时数组1 [c] ＝ -1
跳出循环 ()
.如果真结束
处理事件 ()
.计次循环尾 ()
.计次循环尾 ()
.计次循环尾 ()
清除数组 (窗口句柄数组)
.计次循环首 (取数组成员数 (临时数组1), a)
.如果真 (临时数组1 [a] ≠ -1)
加入成员 (窗口句柄数组, 临时数组1 [a])
.如果真结束
处理事件 ()
.计次循环尾 ()
.计次循环首 (取数组成员数 (窗口句柄数组), a)
_窗口取外边框 (窗口句柄数组 [a], 临时矩形坐标)
临时窗口比例.句柄 ＝ 窗口句柄数组 [a]
临时窗口比例.顶边 ＝ (临时矩形坐标.矩形顶边 － (坐标.y － 顶级矩形坐标.矩形顶边) － 顶级矩形坐标.矩形顶边) ÷ 高度_
临时窗口比例.左边 ＝ (临时矩形坐标.矩形左边 － (坐标.x － 顶级矩形坐标.矩形左边) － 顶级矩形坐标.矩形左边) ÷ 宽度_
临时窗口比例.宽度 ＝ (临时矩形坐标.矩形右边 － 临时矩形坐标.矩形左边) ÷ 宽度_
临时窗口比例.高度 ＝ (临时矩形坐标.矩形底边 － 临时矩形坐标.矩形顶边) ÷ 高度_
' 调试输出 (临时窗口比例.顶边, 临时窗口比例.左边, 临时窗口比例.宽度, 临时窗口比例.高度)
加入成员 (窗口比例, 临时窗口比例)
处理事件 ()
.计次循环尾 ()
返回 (取数组成员数 (窗口比例))
.子程序 事件_, , 公开
.局部变量 a, 整数型
.局部变量 顶级矩形坐标, 矩形坐标
.局部变量 临时矩形坐标, 矩形坐标
.局部变量 临时窗口比例, 窗口比例
.局部变量 宽度_, 整数型
.局部变量 高度_, 整数型
.局部变量 局_类名, 文本型
.局部变量 宽度2_, 整数型
.局部变量 高度2_, 整数型
取窗口内大小 (顶级句柄, 宽度_, 高度_)
_窗口取外边框 (顶级句柄, 顶级矩形坐标)
.计次循环首 (取数组成员数 (窗口比例), a)
窗口移动 (窗口比例 [a].句柄, 窗口比例 [a].左边 × 宽度_, 窗口比例 [a].顶边 × 高度_, 窗口比例 [a].宽度 × 宽度_, 窗口比例 [a].高度 × 高度_)
_窗口更新 (窗口比例 [a].句柄)
处理事件 ()
.计次循环尾 ()

用了超级模块。以上是类 复制到类模块里

.版本 2.支持库 iext
.程序集 窗口程序集1.程序集变量 窗口移动类, 窗口移动类
.子程序 __启动窗口_创建完毕
.局部变量 b, 整数型
.局部变量 a, 整数型

窗口移动类.初始化 (_启动窗口.取窗口句柄 ())

.子程序 __启动窗口_尺寸被改变
窗口移动类.事件_ ()

以上是窗口事件 复制到窗口事件里

.版本 2
.数据类型 窗口比例
.成员 句柄, 整数型
.成员 顶边, 双精度小数型
.成员 左边, 双精度小数型
.成员 宽度, 双精度小数型
.成员 高度, 双精度小数型

以上是自定义数据类型

追问

能不用模块吗？

追答

可以不用。调用几个API就可以了
懒的去找。。。

Answer 2

在代码里面弄比如说：编辑框1.左边=_启动窗口.左边编辑框1..顶边=_启动窗口.顶边编辑框1.宽度=_启动窗口.宽度编辑框1.高度=_启动窗口.高度

Answer 3

我能想到的只有百分比。

其他的就得你自己慢慢去算了。

 

http://hi.baidu.com/laimoxuan